使用LibreOffice Basic遍历控件

Question

I'd like to iterate over Controls in a LibreOffice form with Basic.

Basically, I'd like to do what this code does in VBA.

Sub parcours_controles_formulaire()
    Dim cControl As Control
    Dim sLog As String
    sLog = "List of controls : " & vbCrLf 
    For Each cControl In FrmExemplesControles.Controls
        sLog = sLog & _
        cControl.Name & _
        " of type " & _
        TypeName(cControl) & vbCrLf
    Next cControl
    MsgBox sLog
End Sub

EDIT : Here is what I found with Lyrl's help. That's not totally correct yet. I'm not able to get the labels of controls.

Sub iterate_forms_controls()
    Dim Dlg As Object
    Dim Controls As Object
    Dim cControl As Object
    Dim I As Integer
    Dim A As String

    DialogLibraries.LoadLibrary("Standard")
    Dlg = CreateUnoDialog(DialogLibraries.Standard.BoiteDeDialogue1)

    Controls = Dlg.Controls

    I = 0
    A = ""
    For Each cControl In Controls
        I = I + 1
        A = A & cControl.getImplementationName()
        'A = A & cControl  ' How to get back the label of cControl here ?
    Next cControl

    MsgBox "There is " & i & " controls in that form !" & A
End Sub

Answer 1

Note: this code was tested in OpenOffice. I believe it will work the same way in LibreOffice.

Controls are located on the drawpage. If there might be non-control drawpage objects (arrows, shapes, images, etc.) and you want to operate just on controls, you have to iterate through all the draw objects and test each one for being a control:

Sub iterate_forms_controls()
    Dim oDP As Object : oDP = ThisComponent.drawpage
    Dim cControl As Object
    Dim i As Integer

    REM The oDP assignment above is for a standard form (a Writer document).
    REM If you are using a Calc document as a form you would instead write:
    REM oDP = ThisComponent.Sheets.getByName("SheetName").drawpage

    For i = 0 To oDP.Count - 1
    cControl = oDP.getByIndex(i)
        If cControl.supportsService("com.sun.star.drawing.ControlShape") Then
            'Do something
        End If
    Next i
End Sub

Edit: I looked at the object "cControl" with XRay. Looked through the properties, and nothing looked useful. I then went to methods and found a method "getModel". Double-clicked on getModel to XRay that method, and found "Label" with the name I'd given the checkbox. Woot! (I've worked with other objects that have certain properties only accessible through a "model"; it's not an intuitive place to look.)

So try this:

For Each cControl In Controls
    I = I + 1
    A = A & cControl.getModel.Label
Next cControl