将列或行添加到csv文件（matlab或cmd）

Question

This is a very common question I believe but I could not find an accurate enough answer. I need an answer either using MATLAB or using a simple enough command line prompt. I have (many) .csv files in a directory which all are similar. Say the files look like,

1,2
3,4

I now want them to all look like

,c1,c2
t1,1,2
t2,3,4

I am not a 100% sure on how to format the entries correctly on StackExchange. There is no blank line between the first and secnd row. What I am doing is - I add a column "t1 t2..." and row "c1 c2..." to all the files. The very first cell in the file is blank. I need this done to all files in my directory. Of course the t1 t2 values and c1 c2 values should run for the entire size of the file.

How do I accomplish this?

Answer 1

Here's another awk script:

#!/usr/bin/awk -f

BEGIN { FS=OFS="," }
{
    if( FNR==1 ) {
        close(fn); fn=FILENAME ".new"; printf OFS > fn

        for(i=1; i<=NF; i++) {
            printf "c%d%s", i, (i!=NF) ? OFS:"\n" > fn
        }
    }
    print "t"FNR OFS $0 > fn
}

which does the following:

• BEGIN { FS=OFS="," } - sets the field separators to ,`
• FNR==1 - In the first line of each input file, close(fn) in case it's open, set fn equal to "your filename.new", then print a single leading , . FNR is the line number in the current file.
• Also create the c# headers, based on the number of fields in the first data row and print those to fn .

Then, treat all lines like they are valid data lines( no comments ):

• Prepend a t# OFS to each data row and then print it to fn

I placed the awk script into a file script.awk and then chmod +x script.awk .

Given the following two input data files ( data1 and data2 ) in the same directory:

cat data1 data2
1,2 
3,4 
1,2,3
4,5,6
7,8,9

and running the script like script.awk data* gives the following two .new data files:

cat data1.new data2.new
,c1,c2
t1,1,2 
t2,3,4 
,c1,c2,c3
t1,1,2,3
t2,4,5,6
t3,7,8,9

As long as the file names are similar to each other and don't match the script's name, it should be easy to pass them all to the script. I didn't anything to align the columns as the numbers increase in length, just enough to give one leading space to the c# row.

Answer 2

You should show some code you have tired and if it doesn't work, you can ask the people on stack overflow, Most people here won't even help you without code. Here is an outline of what to do, you can implment it in your favorite programming language/environment

1. create a new output file
2. Open your existing csv file
3. Add your new rows to the top of the output file (c1 c2 c3..)

4. for each line in csv

   now we are trying to create each line in the output file

   a. split line using spaces (or some other delimiter)

   b. write t1 to output and insert delimiter

   c. write the 1st and 2nd "tokens" from your split

   d. write t2 to output and insert delimter

   e. write the remain columns to the line

   f. insert newline character in output file

5. close both csv and output file

optional "overwriting" the original csv

6. delete original csv
7. rename output file to your old csv file name

Answer 3

awk '{
      FS=" "
      if (NR == 1) {
         printf ("%s", FS)
         for (col=1;col < NF;col++) printf( "c%d%s", col, FS)
         printf( "c%d\n", NF)
         }
     if ( $0 !~ /^[[:space:]]*$/ ) {
         printf ( "t%d%s%s\n", NR, FS, $0)
         }
     }' YourFile

• assume here (strange for a csv) that space is the separator, for any more traditionnal separator, just adapt the FS=" " with your separator value
• add your header column on first line
• add the tX start of line
• take 1st line as reference for number of column in header

add a find ... or batch loop to change it in every csv you have in your folder

Answer 4

Using GNU awk 4.* for -i inplace :

$ cat tst.awk
BEGIN { FS=OFS="," }
FNR==1 {
    for (i=1;i<=NF;i++)
        printf "%sc%d%s",(i>1?"":OFS),i,(i<NF?OFS:ORS)
}
{ print "t" FNR, $0 }

$ cat file
1,2
3,4

$ awk -i inplace -f tst.awk file

$ cat file
,c1,c2
t1,1,2
t2,3,4

Just change file to * and it'll update every file in your directory.