如何在excel vba宏中拆分字符串忽略最后一部分

Question

I have a cell which contains path values like:

C:/Videos/New/VideoName.mp4

I wanted to take only the path from that cell

So I tried

elementArray = Split(Cells(4, 2), "/")

So that I can concatenate the strings inside that array everytime

But the array is still having the full path

ie

elementArray[0]=C:/Videos/New/VideoName.mp4

How can ignore the file name and take the path alone?

Answer 1

There seems to be some confusion on whether you are using and/or require forward slashes (eg / or Chr(47) ) or back-slashes (eg \\ or Chr(92) ). Try something like this:

dim sPath as string, sFullPath as string
sFullPath = "C:/Videos/New/VideoName.mp4"   ' or C:\Videos\New\VideoName.mp4
if len(sFullPath) > len(replace(sFullPath, Chr(47), vbnullstring)) then
    sPath = replace(sFullPath, split(sFullPath, Chr(47))(ubound(split(sFullPath, Chr(47)))), vbnullstring)
    debug.print sPath & " with forward slashes"
elseif len(sFullPath) > len(replace(sFullPath, Chr(92), vbnullstring)) then
    sPath = replace(sFullPath, split(sFullPath, Chr(92))(ubound(split(sFullPath, Chr(92)))), vbnullstring)
    debug.print sPath & " with back-slashes"
else
    debug.print "unknown separator"
end if

Look to the VBE's Immediate window ( Ctrl + G ) for the results.

Answer 2

To avoid any issue, I would use the GetParentFolderName() method of the FileSystemObject , accessible by adding the reference Microsoft Scripting Runtime .

Dim fso As New FileSystemObject
parentFolder = fso.GetParentFolderName("your path")

Or in late-binding, as suggested by @SOofWXLS (so you avoid the early-binding of the library into the project):

Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")
parentFolder = fso.GetParentFolderName("your path")

I think it's the easiest and most robust way of parsing the parent folder by the full path: you avoid complex string manipulations that might let some "less common" cases apart (eg a Mac's path won't be parsed by the "manual" methods).

Answer 3

You could use the InStrRev() function:

With Cells(4, 2)
    MsgBox Mid(.Value, 1, InStrRev(.Value, "\") - 1)
End With

Answer 4

Please, read Jeeped comment to the question.

I would suggest to use StrReverse and InStr functions instead of Split :

Dim s As String, f As String

s = "C:\Videos\New\VideoName.mp4"
f = StrReverse(s)
'FileName
'f = Left(f, InStr(1, f, "\") - 1)
'Path
f = Right(f, InStr(1, f, "\"))
f = StrReverse(f)
MsgBox f

'returns: VideoName.mp4 or path - read above comments