检查列值的顺序是相同的awk / bash

Question

I have an input file:

A 23
A 45
A 32
A 61
A 78
B 23
B 45
B 32
B 61
B 78
C 23
**C 32
C 45**
C 61
C 78

The first column specifies a group, and the second column specifies some values for that group.

I want to check if the order of values for each group is the same.

For example, the values are 23,45,32,61,78 for group A. The values are in the same order for group B. But in group C there is a violation of the order (in bold), therefore the output should simply be "false".

If group C, the order of values is followed as well, the output would be "true".

Note that the groups in the first column are all unique, there is no repeated group.

Answer 1

!f { a[++i] = $2 }              # save first sequence
NR>1 && $1!=p { f=1; i=1 }      # set flag and reset index on new sequence
{ p=$1 }                        # save value of first column
f && a[i++]!=$2 { m=1; exit }   # if number not in sequence, set m and exit early
END { print m?"false":"true" }  # print false or true, depending on m

Run it like awk -f script.awk file

Answer 2

This awk should work:

awk '$1 != p {
   if (!grp1 && grp)
      grp1 = grp;
  if (grp != grp1) {
     print p " - false";
     done = 1;
     exit
  };
  grp = "";
  p = $1
}
{
   grp = grp ":" $2
}
END {
  if (!done && grp != grp1)
     print p " - false"
}' file

It prints:

C - false

Answer 3

Another solution:

 NR == 1 {
    initial = $1
    returnVal = ""
}
{
    if (initial == $1) {
        array[++i] = $2
    } else {
        if (anchor != $1)
            ix = 0
        anchor = $1
        if (array[++ix] != $2) {
            returnVal = 1
        }
    }
}
END {
    print (returnVal) ? "false" : "true" ;
}