尝试使用VBA（Excel）更改多个数据透视表筛选器时出现错误424

Question

I'm writing a code to automatically change 3 filters on multiple pivot tables simultaneously upon pressing a button. There are two worksheets, one named MASTER that holds the button and 3 drop-down boxes for specifying a Year, Month, and Week, the other named PIVOTS which, obviously, holds all the pivot tables (and nothing else).

The code I've written here works EXCEPT when I have "All" selected for the Week criteria. Our SQL cube formats weeks in the following format: YYYY-MM-DDT00:00:00. I have a helper formula that checks whether or not what's chosen for Week is "All" or a date; if "All" is chosen, it adds nothing, but if a date is chosen, it will add "T00:00:00" to the end of the date to create the correct format. When a date is chosen, the macro works, but when All is chosen, I get a "Run-time error '424': Object Required."

Here is the code:

Sub ChangeCubesMonth()
 Dim PT As PivotTable
 Dim rWeek As Range
 Dim rMonth As Range
 Dim rYear As Range
 Dim sWeek As String
 Dim sMonth As String
 Dim sYear As String


'Define ranges
Set rWeek = ThisWorkbook.Sheets("MASTER").Range("Y18")
Set rMonth = ThisWorkbook.Sheets("MASTER").Range("Y2")
Set rYear = ThisWorkbook.Sheets("MASTER").Range("E1")

'Define strings
sWeek = "[Time Date].[Workforce Week].&[" & rWeek & "]"
sMonth = "[Time Date].[Month].&[" & rMonth & "]"
sYear = "[Time Date].[Year].&[" & rYear & "]"

On Error GoTo errHandler
For Each PT In Sheets("PIVOTS").PivotTables
    With PT.PivotFields("[Time Date].[Workforce Week].[Workforce Week]")
        .ClearAllFilters
        .CurrentPageName = sWeek
    End With

    With PT.PivotFields("[Time Date].[Month].[Month]")
        .CurrentPageName = sMonth
    End With

    With PT.PivotFields("[Time Date].[Year].[Year]")
        .CurrentPageName = sYear
    End With
Next PT
Exit Sub

errHandler:
MsgBox "Error " & Err.Number & ": " & Err.Description & " in " & _
VBE.ActiveCodePane.CodeModule, vbOKOnly, "Error"

End Sub

When I have a date chosen, this all works perfectly. However, when I have "All" chosen and use Step Into (F8), I get all the way down to the "End With" right after ".CurrentPageName = sWeek" before it goes to the error handler.

I've made sure "All" is the correct word to use in the VBA code to set the filter correctly, and at this point I'm stumped as to why it only doesn't work when All is selected. Any help would be appreciated!

Answer 1

Found the issue...It didn't like the & symbol before the last set of brackets when All is selected. I added this bit of code:

'Define strings
If rWeek = "All" Then
    sWeek = "[Time Date].[Workforce Week].[All]"
Else
    sWeek = "[Time Date].[Workforce Week].&[" & rWeek & "]"
End If

And now the code works fine.