VBA Access / Excel-切换读/写

Question

Using VBA Access

Is there a more efficient way of making an open read only excel file to read/write mode? Or check if read only is true wait till read/write is active

I created a continuous loop that opens and closes the file till read/write is active. However sometimes it works sometimes it doesn't, frustrating.

I've looked into toggling read/write also Changefileaccess even SETATTR functions

Dim xl As Object

Set xl = CreateObject("Excel.Application")


Do Until xl.ActiveWorkbook.ReadOnly = False
xl.Quit
xl.Workbooks.Open ("C:\TEST\Test.xlsb")
If xl.ActiveWorkbook.ReadOnly = False Then Exit Do
Loop

Answer 1

Few observations:

1. There is a possibility that your code can go into an endless loop. Give some wait time before you recheck again.
2. Define the number of times the code should attempt re-opening.
3. Don't use CreateObject . CreateObject creates a new applicaiton. Use GetObject if you want to work with the already open file.
4. Check if the attribute is read only before you re-open the file.

See this example ( Untested )

Sub Sample()
    Dim objxlAp As Object, objxlWb As Object
    Dim FlName As String
    Dim NumberOfAttempt As Long

    FlName = "C:\TEST\Test.xlsb"

    Set objxlAp = GetObject(, "Excel.Application")
    Set objxlWb = objxlAp.ActiveWorkbook

    Do Until objxlWb.ReadOnly = False
        objxlWb.Close (False)

        If GetAttr(FlName) = vbReadOnly Then _
        SetAttr FlName, vbNormal

        objxlAp.Workbooks.Open (FlName)

        If objxlWb.ReadOnly = False Then Exit Do

        Wait 60 '<~~ Wait for 60 seconds. Change as Applicable
        NumberOfAttempt = NumberOfAttempt + 1

        If NumberOfAttempt > 5 Then
            MsgBox "Tried reopening the file 5 times. Unable to do it. Exiting the loop"
            Exit Do
        End If
    Loop
End Sub

Private Sub Wait(ByVal nSec As Long)
    nSec = nSec + Timer
    While nSec > Timer
        DoEvents
    Wend
End Sub

Important Note : A workbook can me made Read-Only using these two means

1. Right click on the file and set attribute as ReadOnly
2. File Save As - Read Only Recommended. The above code is not for this method.

My Assumptions :

You are not on a network where the file has been opened by a different user.

Answer 2

Can you check using GetAttr :

If ((GetAttr("C:\tmp\Test.xlsb")) And vbReadOnly) Then
Debug.Print "Do something, file is read only"
End If

Maybe change this property before open file?

Sub OpenRW()

Dim wb As Workbook

Set wb = Workbooks.Open("C:\tmp\Test.xlsb")
Debug.Print "1. ReadOnly? " & ActiveWorkbook.ReadOnly 'read only
wb.Close
SetAttr "C:\tmp\Test.xlsb", vbNormal
Set wb = Workbooks.Open("C:\tmp\Test.xlsb") 'read/write
Debug.Print "2. ReadOnly? " & ActiveWorkbook.ReadOnly
wb.Close
SetAttr "C:\tmp\Test.xlsb", vbReadOnly
Set wb = Workbooks.Open("C:\tmp\Test.xlsb")
Debug.Print "3. ReadOnly? " & ActiveWorkbook.ReadOnly 'read only
wb.Close

End Sub

Results:

OpenRW
1. ReadOnly? True
2. ReadOnly? False
3. ReadOnly? True