带有Count和Countif公式VBA的运行时错误1004

Question

I am getting run time error 1004 when converting the following formula to code:

When I try to consider the only Count forumlas, it was working.

Formula:

=(COUNT(C25:C26)-COUNTIF(C25:C26,0))/(COUNT(E25:E26)-COUNTIF(E25:E26,0))

Code:

Sheets("Sheet1").Cells(29, 3).Formula = "=(COUNT(" & Sheets("Sheet1").Range(Cells(25, 3), Cells(26, 3)).Address(False, False) _
& "- COUNTIF(" & Sheets("Sheet1").Range(Cells(25, 3), Cells(26, 3)).Address(False, False) & ",0 )/" & _
"(COUNT(" & Sheets("Sheet1").Range(Cells(25, 5), Cells(26, 5)).Address(False, False) _
& "- COUNTIF(" & Sheets("Sheet1").Range(Cells(25, 5), Cells(26, 5)).Address(False, False) & ",0 ))"

Answer 1

Don't make it to confusing,

Range("C29") = _
"=(COUNT(Sheet1!R[-4]C:R[-3]C)-COUNTIF(Sheet1!R[-4]C:R[-3]C,0))/(COUNT(Sheet1!R[-4]C[2]:R[-3]C[2])-COUNTIF(Sheet1!R[-27]C[2]:R[-4]C[2],0))"
'or
Range("C29") = _
"=(COUNT(Sheet1!C25:C26)-COUNTIF(Sheet1!C25:C26,0))/(COUNT(Sheet1!E25:E26)-COUNTIF(Sheet1!E2:E25,0))"

Answer 2

Further to my comments, this is how you will qualify your cells object. Notice the DOT before cells?

Tested

Sub Sample()
    Dim ws As Worksheet
    Dim sFormula As String

    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        sFormula = "=(COUNT(" & _
                    .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ")" & _
                    "- COUNTIF(" & _
                    .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0 ))/" & _
                    "(COUNT(" & _
                    .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ")" & _
                    "- COUNTIF(" & _
                    .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0 ))"

        Debug.Print sFormula

        .Cells(29, 3).Formula = sFormula
    End With
End Sub

Answer 3

You forgot some brakets/parenthesis and let spaces .

With Sheets("Sheet1")
    .Cells(29, 3).Formula = _
    "=(COUNT(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) _
    & ")-COUNTIF(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0))/" & _
    "(COUNT(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) _
    & ")-COUNTIF(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0))"
End With

Use a string variable to debug and prompt it with a MsgBox .

Dim StrFormula As String
With Sheets("Sheet1")
    StrFormula = _
    "=(COUNT(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) _
    & ")-COUNTIF(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0))/" & _
    "(COUNT(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) _
    & ")-COUNTIF(" & .Range(.Cells(25, 3), .Cells(26, 3)).Address(False, False) & ",0))"
End With
MsgBox StrFormula