向特定的xml标签添加显式命名空间属性

Question

In a quick-and-dirty conversion from XML generated by one program (htlatex) to another (ArborText Editor), I need to replace all XML of the following form

<math xmlns="http://www.w3.org/1998/Math/MathML">
<mn>
....
</mn>
</math>

with

<m:math xmlns:m="http://www.w3.org/1998/Math/MathML">
<m:mn xmlns:m="http://www.w3.org/1998/Math/MathML">
....
</m:mn>
</m:math>

Is there a cleaner easy way to achieve this rather than searching for tags <math , <mn> etc. and replacing them? Or can this be done via xslt?

Answer 1

Disclaimer : I am going to use regex to this! If you are afraid They might get you, stop reading now.

---

Because this is a very limited kind of problem, I believe using an XML parser to find the things we want to change and then using regex is ok here. We are not trying to parse anything with the regex, just replacing simple text patterns.

I used XML::Twig to find all the math nodes, grabber their XML as a string, replaced the namespaces and put the XML back, which makes XML::Twig parse the altered string. If the regex manipulation broke something to the extend that it's invalid, we will notice here because the parsing will fail.

Of course this asumes there are no other namespaces inside the math elements.

use strict;
use warnings;
use XML::Twig;

my $xml = <<XML;
<container>
<math xmlns="http://www.w3.org/1998/Math/MathML">
<mn>
<foo>asdf</foo>
<bar>fdsa</bar>
</mn>
</math>
</container>
XML

my $t = XML::Twig->new(
    pretty_print  => 'indented',
    twig_handlers => {
        math => sub {
            my $new_xml = $_->outer_xml;
            $new_xml =~ s{ xmlns="http://www.w3.org/1998/Math/MathML"}{};
            $new_xml =~ s{<([a-zA-Z]+)}{<m:$1 xmlns:m="http://www.w3.org/1998/Math/MathML"}g;
            $new_xml =~ s{</}{</m:}g;

            $_->set_outer_xml($new_xml);
        },
    }
);
$t->parse($xml);
$t->print;

Output contains the namespace in each element starting from math .

<container>
  <m:math xmlns:m="http://www.w3.org/1998/Math/MathML">
    <m:mn xmlns:m="http://www.w3.org/1998/Math/MathML">
      <m:foo xmlns:m="http://www.w3.org/1998/Math/MathML">asdf</m:foo>
      <m:bar xmlns:m="http://www.w3.org/1998/Math/MathML">fdsa</m:bar>
    </m:mn>
  </m:math>
</container>

I verified that it works for more deeply nested structures and multiple math elements.