得到文本正文中的最后一个单词

Question

Given a body of text than can span a varying number of lines, I need to use a grep , sed or awk solution to search through many files for the same pattern and get the last word in the body.

A file can include formats such as these where the word I want can be named anything

call function1(input1,  
               input2,    #comment  
               input3)    #comment  
               returning randomname1,    
             randomname2,  
                 success3

call function1(input1,
               input2,    
               input3)    
               returning randomname3, 
randomname2, 
randomname3


call function1(input1,
               input2,    
               input3)   
               returning anothername3, 
randomname2, anothername3

I need to print out results as

success3
randomname3
anothername3

Also I need some the filename and line information about each .

I've tried

pcregrep -M 'function1.*(\s*.*){6}(\w+)$' filename.txt

which is too greedy and I still need to print out just the specific grouped value and not the whole pattern. The words function1 and returning in my sample code will always be named as this and can be hard coded within my expression.

Answer 1

Last word of code blocks

Split file in blocks using awk 's record separator RS . A record will be defined as a block of text, records are separated by double newlines.

A record consists of fields, each two consecutive fields are separated by white space or a single newline.

Now all we have to do is print the last field for each record, resulting in following code:

awk 'BEGIN{ FS="[\n\t ]"; RS="\n\n"} { print $NF }' file

Explanation:

• FS this is the field separator and is set to either a newline, a tab or a space: [\\n\\t ] .
• RS this is the record separator and is set to a doulbe newline: \\n\\n
• print $NF this will print the field $ with index NF , which is a variable containing the number of fields . Hence this prints the last field.

Note: To capture all paragraphs the file should end in double newline, this can easily be achieved by pre processing the file using: $ echo -e '\\n\\n' >> file .

Alternate solution based on comments

A more elegant ans simple solution is as follows:

awk -v RS='' '{ print $NF }' file

Answer 2

How about the following awk solution:

awk 'NF == 0 {if(last) print last; last=""} NF > 0 {last=$NF} END {print last}' file

the $NF is getting the value of the last "word" where NF stands for number of fields. Then the last variable always stores the last word on a line and prints it if it encounters an empty line, representing the end of a paragraph.

New version with matches function1 condition.

awk 'NF == 0 {if(last && hasF) print last; last=hasF=""}
  NF > 0 {last=$NF; if(/function1/)hasF=1}
  END {if(hasF) print last}' filename.txt

Answer 3

This will produce the output you show from the input file you posted:

$ awk -v RS= '{print $NF}' file
success3
randomname3
anothername3

If you want to print FILENAME and line number like you mention then this may be what you want:

$ cat tst.awk
NF { nr=NR; last=$NF; next }
{ prt() }
END { prt() }
function prt() { if (nr) print FILENAME, nr, last; nr=0 }

$ awk -f tst.awk file
file 6 success3
file 13 randomname3
file 20 anothername3

If that doesn't do what you want, edit your question to provide clearer, more truly representative and accurate sample input and expected output.

Answer 4

This is the perl version of Shellfish's awk solution (plus the keywords):

perl -00 -nE '/function1/ and /returning/ and say ((split)[-1])' file

or, with one regex:

perl -00 -nE '/^(?=.*function1)(?=.*returning).*?(\S+)\s*$/s and say $1' file

But the key is the -00 option which reads the file a paragraph at a time.