Neo4j / Cypher条件语句，用于加载数据

Question

In Neo4j, is there a simple way to combine WHERE statements to avoid reading through the same file multiple times while simultaneously ignoring NULL values.

For example, is it possible to go through a CSV a single time, and do something like the following

LOAD CSV WITH HEADERS from "file" as line
WITH line, line.FirstNodeID as NodeOneID
WHERE NodeOneID IS NOT NULL
WITH NodeOneID
CREATE (n1:NodeOne { ID : NodeOneID })
WITH line, line.SecondNodeID as NodeTwoID
WHERE NodeTwoID IS NOT NULL
WITH NodeTwoID
CREATE (n2:NodeTwo { ID : NodeTwoID})
;

As of now, the LOAD script will exit if NodeOneID is null even if NodeTwoID is NOT null. How can I build in a simple if-else like condition where the LOAD script will load the proper nodes as long as NodeOneID or NodeTwoID is not null?

UPDATE: Just saw CASE . Gonna check this out real quick..

Answer 1

I think you could do something like this for each line. If the value is not null put it in a collection of one. Then if the collections have an item the node(s) is/are created and if they are empty no nodes are created. If they both have values then both nodes are created.

LOAD CSV WITH HEADERS from "file" as line
WITH line
, case when line.FirstNodeID is not null then [line] else [] end as NodeOneID
, case when line.SecondNodeID is not null then [line] else [] end as NodeTwoID
foreach(x in NodeOneID | CREATE (n1:NodeOne { ID : x.FirstNodeID }))
foreach(x in NodeTwoID | CREATE (n2:NodeTwo { ID : x.SecondNodeID }))

Answer 2

Does this work for you?

LOAD CSV WITH HEADERS from "file" as line
foreach(x in COALESCE(line.FirstNodeID)  | CREATE (:NodeOne { ID : x }))
foreach(x in COALESCE(line.SecondNodeID) | CREATE (:NodeTwo { ID : x }));