从FTP服务器获取文件并将其复制到UNC目录

Question

I am trying to copy a CSV file from an FTP server to a UNC file path. I had it working from FTP to a local path, but it would be better for my project to have it copy to a UNC path. This must all be achieved in batch and FTP commands.

This is my code so far:

for /f "delims=" %%x in (config.bat) do (set "%%x")
echo Start[%time%] >> "%primefolder%\TimeRun.log"
REM --------------------------------------------------------------------------------------------
REM  Import .csv from the ftp server - csv imported to local directory
REM         Ftpcmd.txt connects to the ftp server and copies the .csv file to a local directory
REM --------------------------------------------------------------------------------------------
echo open %FTPIP%> %primefolder%\ftpcmd.txt
echo %FTPUsername%>> %primefolder%\ftpcmd.txt
echo %FTPPassword%>> %primefolder%\ftpcmd.txt
echo cd %FTPPrimary%>> %primefolder%\ftpcmd.txt
echo binary>> %primefolder%\ftpcmd.txt
echo lcd /D "%offload%" >> %primefolder%\ftpcmd.txt
echo mget %Filename%>> %primefolder%\ftpcmd.txt
echo disconnect>> %primefolder%\ftpcmd.txt
echo quit>> %primefolder%\ftpcmd.txt
REM -----------------------------------------------------------------------------------------------------------------------------
REM  Call and execute the FTP command text document (ftpcmd.txt)
REM         This Code calls the file which establishes a connection and then copies the file to a local directory   
REM         Dynamic FTP command file is created and populated.
REM -----------------------------------------------------------------------------------------------------------------------------
ftp -i -s:"%primefolder%\ftpcmd.txt" >"%primefolder%\logs\ftpinport.log" 2>>"%primefolder%\logs\ftperr.log"
echo[%date% - %time%] >> "%primefolder%\logs\ftpinport.log" 
ftp -i -d -s:%primefolder%\ftpcmd.txt
for /f "tokens=*" %%a in (%primefolder%\logs\ftperr.log) do (echo [%date% - %time%]  [Error Level: 1][Issue Location:FTP][Error:%%a] >> "%primefolder%\logs\error.log")

This is the config file:

primefolder=C:\scripts
FTPIP=111.11.1.1
FTPUsername=User
FTPPassword=test
Filename=User.csv
FTPPrimary=\CSV\
FTPArchive=\CSV\Archive
offload=\\test.org\test_this\Implementation\New Projects\New\Interface

Thank you for all your help ahead of time!

---

After changing mget to get as suggested in an answer by @Martin Prikryl , I am getting this error:

R:I/O Error

This is the ftp output:

ftp> open 111.11.1.1
Connected to 111.11.1.1.
220 Welcome to Code-Crafters Ability FTP Server.
User (111.11.1.1:(none)): 
331 Please send PASS now.

230-Welcome "User".
230-There are currently 1 of 100 users logged onto this server.
230-There are currently 1 users logged onto this account.
230-You have unlimited KB of account allocation left.
230-You have 0 transfer credits remaining.
230-You lose 0 credits per KB downloaded.
230-You lose 0 credits per KB uploaded.
230 You are currently in directory "/".
ftp> cd \CSV\
250 "/CSV" is current directory.
ftp> binary
200 Type set to 'I' (IMAGE).
ftp> get User.csv \\test.org\test_this\Implementation\New Projects\New\Interface\User.csv 
200 PORT command successful.
150 Data connection established, beginning transfer.
226 Transfer complete.
ftp: 1277532 bytes received in 2.64Seconds 483.91Kbytes/sec.
ftp> disconnect
221 Thanks for visiting.
ftp> quit

---

When redirecting the error and output of ftp to one file I get this as the output:

 ftp> open 111.11.1.1
    Connected to 111.11.1.1
    220 Welcome to Code-Crafters Ability FTP Server.
    User (111.11.1.1:(none)): 
    331 Please send PASS now.

    230-Welcome "User".
    230-There are currently 2 of 100 users logged onto this server.
    230-There are currently 1 users logged onto this account.
    230-You have unlimited KB of account allocation left.
    230-You have 0 transfer credits remaining.
    230-You lose 0 credits per KB downloaded.
    230-You lose 0 credits per KB uploaded.
    230 You are currently in directory "/".
    ftp> cd \CSV\
    250 "/CSV" is current directory.
    ftp> binary
    200 Type set to 'I' (IMAGE).
    ftp> get User.csv \\test.org\test_this\Implementation\New Projects\New\Interface\User.csv  
    200 PORT command successful.
    150 Data connection established, beginning transfer.
    > R:I/O Error
    226 Transfer complete.
    ftp: 1277532 bytes received in 2.84Seconds 449.20Kbytes/sec.
    ftp> disconnect
    221 Thanks for visiting.
    ftp> quit

Answer 1

UNC path cannot be a working directory in Windows.

So lcd \\\\example.com\\share won't work.

The mget command does not allow your to specify a target path.

But you do not seem to need the mget , as you are not using a wildcard, but downloading a specific file.

So you can use the get command instead, which allows you to specify a target path.

echo get %Filename% "%offload%\%Filename%" >> %primefolder%\ftpcmd.txt

Also note that as your %offload% path contains a space ( New Projects ) you need to enclose the path to double-quotes.

And finally remove the

echo lcd /D "%offload%" >> %primefolder%\ftpcmd.txt

Side note: There's no /D switch to the FTP lcd command (there are no switches in the Windows ftp.exe whatsoever).

---

Had you need to use the wildcard, you would have to use a different FTP client.

For example with WinSCP scripting you can use:

winscp.com /log=winscp.log /command ^
    "open ftp://%FTPUsername%:%FTPPassword%@%FTPIP%/" ^
    "cd %FTPPrimary%" ^
    "get %Filename% %offload%\" ^
    "exit" > "%primefolder%\logs\ftpinport.log" 

Note that the WinSCP get command supports wildcards and allows you to specify target path at the same time. WinSCP also defaults to binary transfer mode.

References:

• Automating FTP file transfers with WinSCP ;
• Converting Windows FTP script to WinSCP script .

(I'm the author of WinSCP)