使用XSLT的XML合并节点

Question

I have xml file like that:

<root>
 <scenario name="film1">
  <case name="aaa">
    <test name="test1">ok</test>
  </case>
  <case name="bbb">
    <test name="test2">not ok</test>
  </case>
  <case name="aaa">
    <test name="test3">not ok</test>
  </case>
  <case name="bbb">
    <test name="test66">ok</test>
  </case>
 </scenario>
</root>

Of course there is more nodes like scenario but i want group case for each scenario. I expect something like that:

<root>
 <scenario name="fil1">
  <case name="aaa">
    <test name="test1">ok</test>
    <test name="test3">not ok</test>
  </case>
   <case name="bbb">
    <test name="test2">not ok</test>
    <test name="test66">ok</test>
  </case>
 </scenario>
</root>

I made xslt file:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
  <xsl:template match="scenario">
    <scenario>
      <xsl:attribute name="name">
        <xsl:value-of select="@name"/>
      </xsl:attribute>
      <xsl:apply-templates/>
    </scenario>
  </xsl:template>
  <xsl:template match ="case">
    <case>
      <xsl:attribute name="name">
        <xsl:value-of select="@name"/>
      </xsl:attribute>
    </case>
  </xsl:template>
</xsl:stylesheet>

DO you know what i should do now?

Answer 1

I would use something like this...

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

  <xsl:template match="scenario">
    <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates/>
        </xsl:copy>
  </xsl:template>

  <xsl:template match ="case">
    <xsl:param name="thisName">
      <xsl:value-of select="@name" />
    </xsl:param>
    <xsl:if test=".=/root/scenario/case[@name=$thisName][1]">
      <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:apply-templates select="/root/scenario/case[@name=$thisName]/test" />
      </xsl:copy>
    </xsl:if>
  </xsl:template>

  <xsl:template match ="test">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match ="@*">
    <xsl:copy />
  </xsl:template>
</xsl:stylesheet>

Answer 2

Standard approach in xslt 1.0 - muenchian grouping.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:key name="case-by-name" match="case" use="@name"/>
    <xsl:key name="test-by-case" match="test" use="parent::*/@name"/>

    <xsl:template match="/root">
        <xsl:copy>
            <xsl:apply-templates select="*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="scenario">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <!-- process only first cases in groups -->
            <xsl:apply-templates select="case[generate-id() = generate-id(key('case-by-name', @name)[1])]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="case">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <!-- copy all tests for corresponding case name -->
            <xsl:copy-of select="key('test-by-case', @name)"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 3

You say in your question you want to group case for each scenario . If you do have multiple scenario elements, and want to group the case elements within each such element, you would need to make use of a concatenated key:

<xsl:key name="case" match="case" use="concat(../@name, '|', @name)" />

This means if you had two case elements with the same name , but in different scenario elements, then they would still be grouped separately.

Now, for the grouping, for each case statement within a scenario , you need to find the case elements that occur first in the key for its given attributes. This can be done as follows:

<xsl:apply-templates select="case[generate-id() = generate-id(key('case', concat(../@name, '|', @name))[1])]" />

To break it down...

key('case', concat(../@name, '|', @name)) - Gets all elements with the same attributes

key('case', concat(../@name, '|', @name))[1] - Gets the first element of that list

generate-id(key('case', concat(../@name, '|', @name))[1]) - Generates the unique id for that first element, so it can be compared with the current element.

So, effectively, you get the distinct elements. You can then get the items in the "group" using the key again

<xsl:for-each select="key('case', concat(../@name, '|', @name))">

Try this XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="case" match="case" use="concat(../@name, '|', @name)" />
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="scenario">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates select="case[generate-id() = generate-id(key('case', concat(../@name, '|', @name))[1])]" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match ="case">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:for-each select="key('case', concat(../@name, '|', @name))">
                <xsl:apply-templates />
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

As mentioned in comments, the definitive article on this approach can be found at http://www.jenitennison.com/xslt/grouping/muenchian.html , so it is worth reading it, and re-reading it, then practising it, until you finally understand it.

Also, note the use of the Identity Transform , which means you don't have to write a template for each specific element if all you do is want to copy it without changes.