Outlook VBA交换收件人

Question

People often forward mails to me and ask me to reply to the original sender, who is in CC. I think it's more neat to put this person in the To field and the forwarder in CC. So I like to swap them. I came up with this piece of VBA:

Sub Swap()
Dim objMail As Outlook.MailItem
Set objMail = Application.ActiveInspector.CurrentItem

With objMail
   a$ = .To
   .To = .CC
   .CC = a$
End With

Set objMail = Nothing
End Sub

Unfortunately, the recipients are copied as text. So Outlook will search for them again in our company's address book. And as it is a large company, sometimes it finds the wrong person, or even claims a person is unknown.

I've experimented with objmail.Recipients but I only got some weird errors. Note: There might be multiple people in both the To and the CC field.

Answer 1

you can fetch the email address out of objMail.Recipients(x).Address . The following code works fine on my machine:

Public Sub Swap()
Dim objOutlook As Outlook.Application ' i use this, because i'm working in MS Access
Dim objMail As Outlook.MailItem
Dim objRecipient As Outlook.recipient
Dim strTo As String
Dim strCC As String

Set objOutlook = GetObject(, "Outlook.Application") ' i use this, because i'm working in MS Access
Set objMail = objOutlook.ActiveInspector.CurrentItem

For Each objRecipient In objMail.Recipients ' here we loop through all recipients

    If objRecipient.type = olTo Then ' check if the current recipient is in To section
        strCC = strCC & ";" & objRecipient.Address ' add it to the CC string

    ElseIf objRecipient.type = olCC Then ' check if the current recipient is in CC section
        strTo = strTo & ";" & objRecipient.Address 'add it to the To string

    End If
Next objRecipient

If strTo <> "" Then
    objMail.To = MID(strTo, 2) ' we cut off the leading semicolon of our string
End If

If strCC <> "" Then
    objMail.CC = MID(strCC, 2) ' same here
End If

Set objMail = Nothing
End Sub

Answer 2

The To property of the MailItem class returns a semicolon-delimited string list of display names for the To recipients for the Outlook item. This property contains the display names only. Instead, the Recipients collection should be used to modify recipients.

You just need to get an instance of the Recipients collection, see the corresponsing property of the MailItem class which returns a collection of Recipient objects for an Outlook item. And then change the Type property of the entries.

Depending on the type of recipient, this property returns or sets an integer corresponding to the numeric equivalent of one of the following constants:

• JournalItem recipient: the OlJournalRecipientType constant olAssociatedContact.
• MailItem recipient: one of the following OlMailRecipientType constants: olBCC , olCC , olOriginator, or olTo .
• MeetingItem recipient: one of the following OlMeetingRecipientType constants: olOptional, olOrganizer, olRequired, or olResource.
• TaskItem recipient: either of the following OlTaskRecipientType constants: olFinalStatus, or olUpdate.