将枚举类型var设置为nil

Question

Maybe (probably) it is a silly question, but I didn't find an answer...

Please, check this hypothetical code:

type
  TCustomType = (Type1, Type2, Type3);

function CustomTypeToStr(CTp: TCustomType): string;
begin
  Result := '';
  case CTp of
    Type1: Result := 'Type1';
    Type2: Result := 'Type2';
    Type3: Result := 'Type3';
  end;
end;

function StrToCustomType(Str: string): TCustomType;
begin
  Result := nil;           <--- ERROR (Incompatible types: 'TCustomType' and 'Pointer')
  if (Str = 'Type1') then
    Result := Type1 else
  if (Str = 'Type2') then
    Result := Type2 else
  if (Str = 'Type3') then
    Result := Type3;
end;

Please, how can I set nil / null / empty to this custom type var, so I can check the function result and avoid problems?

Answer 1

An enumerated type cannot be nil . It must take one of the defined enumeration values.

You have a few options. You can add another enum:

type
  TCustomType = (NoValue, Type1, Type2, Type3);

You can use a nullable type. For instance Spring has Nullable<T> .

You could raise an exception if no value could be found.

function StrToCustomType(Str: string): TCustomType;
begin
  if (Str = 'Type1') then
    Result := Type1 
  else if (Str = 'Type2') then
    Result := Type2 
  else if (Str = 'Type3') then
    Result := Type3
  else
    raise EMyException.Create(...);
end;

Or you can use the TryXXX pattern.

function TryStrToCustomType(Str: string; out Value: TCustomType): Boolean;
begin
  Result := True;
  if (Str = 'Type1') then
    Value := Type1 
  else if (Str = 'Type2') then
    Value := Type2 
  else if (Str = 'Type3') then
    Value := Type3
  else
    Result := False;
end;

function StrToCustomType(Str: string): TCustomType;
begin
  if not TryStrToCustomType(Str, Result) then
    raise EMyException.Create(...);
end;