VBA根据数字数组自动筛选多个工作表，如果不在列表中，则忽略

Question

Let's say I have a workbook with 3 worksheets on it. I've filtered down the first sheet based on column State that equals Ohio . I then get a list of values from that filtered list from column ID and put them into an Integer/Long array. Basically I put all the ID's for each row that has the state column Ohio .

I am now trying to filter the remaining tables based on their ID column where they match my array of ID's . The problem is when it comes across filtered ID's that are not in the new sheet, instead of providing me with the matches for each sheet, I am left with only the last matching value. Here's an example of my VBA trying to filter the remaining sheets:

For Each sheet In Worksheets

If sheet.Name <> "Sheet1" Then
    sheet.Activate        

    columnNum = ActiveSheet.UsedRange.Find("ID").Column
    ActiveSheet.AutoFilterMode = False
    ActiveSheet.UsedRange.AutoFilter

    '***Problem is here
    ActiveSheet.UsedRange.AutoFilter Field:=columnNum, Criteria1:=mainIDs, Operator:=xlFilterValues

End If

Next

As I mentioned earlier mainIDs is an array of Integer that is being carried over to each sheet to filter on. Why is it only bringing me back the last match? Do I need to somehow tell it to ignore filtered values that aren't in the new sheet? How?

EDIT: Here's how I filled my array

Dim mainIDs() As Long, size As Integer, i As Integer

size = ActiveSheet.UsedRange.Columns(1).SpecialCells(xlCellTypeVisible).Cells.Count - 2
ReDim mainIDs(size)

i = 0
For Each row In .UsedRange.Columns(1).SpecialCells(xlCellTypeVisible)
    If row.Value <> "ID" Then '***Column header
        mainIDs(i) = row.Value
        i = i + 1
    End If
Next

Answer 1

If you use an array for filtering you have to cast the values to strings before. As I understood you're adding integer/long values to the array. Autofilter can't work with this.

In addition you have to change your array to a string array mainIDs() as String or declare it as Variant.

For Each row In .UsedRange.Columns(1).SpecialCells(xlCellTypeVisible)
    If row.Value <> "ID" Then '***Column header
        mainIDs(i) = Cstr(row.Value) 'Cast values to string
        i = i + 1
    End If
Next

Then it should work, please let me know if it helped you.

Answer 2

If you use arrays as Criteria , you'll have to use a 1D array.
But then, you need to supply the Operator argument to actually filter all that is in the array.

Sample:

ActiveSheet.UsedRange.AutoFilter Field:=columnNum, _
                                 Criteria1:=mainIDs, _
                                 Operator:xlFilterValues

To know more about AutoFilter Method check MSDN .