“此时，goto是意外的” .bat

Question

I'm making a blackjack gambling simuator using .bat files. At one point i get the error "goto was unexpected at this time". Anyone know a solution to this problem? I have included the section of code that is causing the problem.

    Echo if %%DealerHand%% GTR 21 set DealerStatus=Bust
    Echo if %%DealerHand%%==21 set DealerStatus=Blackjack!
    Echo if %%DealerHand%% LSS 21 set DealerStatus=%%DealerHand%%
    Echo if %%handP4%% GTR 21 set P4status=Bust
    Echo if %%handP4%%==21 set P4status=Blackjack!
    Echo if %%handP4%% LSS 21 set P4status=%%handP4%%
    Echo cls
    Echo Echo Table Number:1
    Echo Echo Dealer:David
    Echo Echo Money:$%%money%%
    Echo Echo Money on table:$%%bet%%
    Echo Echo Players:
    Echo Echo.
    Echo Echo Dealer:Hand:%%DealerStatus%%
    Echo Echo.
    Echo Echo %acctname%:Hand:%%P4status%%
    Echo Echo.
    Echo Echo Enter to continue
    Echo Pause^>nul
    Echo if %%DealerStatus%% == Bust goto winCheck1
    Echo if %%DealerStatus%% == Blackjack! goto DealerWins1
    Echo if %%DealerStatus%% == %%DealerHand%% goto winCheck1
    Echo :winCheck1
    Echo if %%P4hand%% == Bust goto DealerWins1
    Echo if %%P4hand%% == Blackjack! goto P4wins1
    Echo if %%P4hand%% GTR %%DealerHand%% goto P4win1
    Echo if %%P4hand%% LSS %%DealerHand%% goto DealerWins1
    Echo if %%P4hand%% == %%DealerHand%% goto DealerWins1

*PS I'm using this .bat file to generate a new .bat file contianing code. Hence the Echo before every line.

Any help is good help!

Thanks.

Answer 1

Your test for the string "Blackjack!" is going to fail due to the exclamation mark. Try wrapping the test with quotes:

Echo if "%%DealerStatus%%" == "Blackjack!" goto DealerWins1

and

Echo if "%%P4hand%%" == "Blackjack!" goto P4wins1

I suspect however, that there are a few other issues in your code that may be tripping you up. The %P4hand% variable is a number earlier in your code snippet. Are you intending to test %P4status% instead? You may also want to check your use of tag names for consistency as there's P4wins1 as well as P4win1 in use.

Answer 2

The first advice I'll give you is to put ECHO ON at the top of your file (or just remove ECHO OFF if it's there), run it again, and figure out which line has the error. Batch wants to tell you what's wrong, but everybody always suppresses echo even while debugging.

That said, even without knowing which line has the error, my psychic debugging skills tells me that somehow %DealerHand% is the empty string, which causes a syntax error in one of these two lines:

if %%DealerStatus%% == %%DealerHand%% goto winCheck1

if %%P4hand%% == %%DealerHand%% goto DealerWins1

Running that if statement with %DealerHand% undefined or the empty string will give you the error you see. You don't show where DealerHand is set, but if it should not be empty, you'll need to make sure it has a value when you enter this code.

If it is possible that DealerHand has an empty value, then you can guard against the syntax error by wrapping the variable in some characters, so that both sides of the IF always have non-empty strings.

if {%%DealerStatus%%} == {%%DealerHand%%} goto winCheck1

Which evaluates to if {} == {} goto winCheck1 when both variables are null.