计算日期到最近6个月前的季度

Question

What i need is a formula that will calculate the nearest quarter no more than 6 months back. For example, imagine I have today's date in cell A1 - TODAY() – and today´s date is 13/05/2015. I want cell A2 to give me the date of 31/12/2014. As another example, today´s date at 15/03/2015, I want the formula in cell A2 to give me a date of 30/09/2014.

Please, any EXCEL geniuses out there to help?

Answer 1

This answer is based on LibreOffice, but I think it should work in Excel. You need to use EOMONTH function:

=EOMONTH(A1,IF(MOD(MONTH(A1),3)>0,3-MOD(MONTH(A1),3),0))

Explanation: Just calculate the month of the given date (for 13/05/2015, it would be '5'), and then calculate how many months you need to add in order to make it a 'quarter' (3, 6, 9 or 12). In your example, it would be 3-MOD(5,3) = 3-2 = 1. Then just use the EOMONTH funcion to get the last day of the N future month (13/05/2015 + 1 month = 13/06/2015, last day = 30/06/2015).

For the '6 months back' part, just replace A1 with EDATE(A1,-6), in order to calculate the A1 date - 6 months back:

=EOMONTH(EDATE(A1,-6),IF(MOD(MONTH(EDATE(A1,-6)),3)>0,3-MOD(MONTH(EDATE(A1,-6)),3),0))

Hope it helps you.

Answer 2

=IF(MOD(MONTH(TODAY()),3)=0,EOMONTH(TODAY(),-6),IF(MOD(MONTH(TODAY()),3)=1,EOMONTH(TODAY(),-4),EOMONTH(TODAY(),-2)))

I think that this should do what you want it to do.

You didn't mention what version of Excel you were using, so the formula may be different in earlier versions of Excel.

This structure gives you the verbal description of "the nearest quarter no more than 6 months back." however that is not reflected in the example that you gave. You are going to need to take what I gave you and add another set of tests where you work out whether you want the nearest quarter or the nearest quarter greater than 3 months away.

UPDATE

A slightly less elegant way to do this would be to create a 2 x 12 table, your key being 1 through 12 and the value column being the Quarter End date that you want the formula to return. Name the range, something like qtr_ends, then all you need to do is this.

=VLOOKUP(MONTH(TODAY()),qtr_ends,2,0)

That being said, you also have not specified if you are okay with a simple End of Month Quarter End, or if that Quarter End needs to be a business day. If it does, then this becomes much more difficult to do formulaically, and just creating a lookup table where you key is a concatenation of month and year would probably be the best. It is more manual, but it would probably take a lesser amount of time to manually create the table for several years than is would be to actually work all of the logic of getting an EOM date that is also a BD.

Answer 3

您的问题可以使用更多数据“尖点”示例来说明将返回值置于四分之一或另一个范围内的边界线，但这似乎可以满足您的两个示例。

=DATE(YEAR(EDATE(A2, -6)), MROUND(MONTH(EDATE(A2, -6)), 3)+1, 0)

Answer 4

Try this formula

=COUPNCD(EDATE(A1,-6),DATE(9999,12,31),4)

EDATE function gives you the date 6 months back from A1 then COUPNCD function finds the next quarter end date. That works for your two examples but might need tweaking based on your exact requirements - if today is 31/03/2015 what result do you expect?