用户定义的函数调用与在存储过程中调用 UDF

Question

I have a user defined function that is called inside a stored procedure. All that stored procedure does is return the value that is obtained from the UDF scalar function.

However,

Select * UDF_FunctionName(param1,param2) 

udf call is here-

SELECT dbo.udfFunction('1234',10) as result 

and

Exec StoreProcName(param1,param2) 

are returning different results.

StoreProcName calls the `UDF_FunctionName(param1,param2)

sproc code is here-

BEGIN 
 SET NOCOUNT ON; 
 Return SELECT [DbName].[dbo].[udfFunction](@param1, @param2) 
END 

What could be the reason for different results?.

Answer 1

You are trying to use RETURN and SELECT together:

Return SELECT [DbName].[dbo].[udfFunction](@param1, @param2) 

You cannot do that, you either want to return the result, or select it. Depending on which you choose, retrieving the value will differ.

If you do this:

SELECT [DbName].[dbo].[udfFunction](@param1, @param2) 

Then the resultset will have a single row and column containing your value. Access this exactly as you would any other resultset.

If you do this:

RETURN [DbName].[dbo].[udfFunction](@param1, @param2) 

Your stored procedure will have a return value which is the result of your function call. Access this by defining a scalar variable and assigning it to the result of the SP call - assuming the result is INT that might look like

DECLARE @result INT
EXEC @Result = StoredProcName(@param1, @param2)

Answer 2

You should not use RETURN in this way in a stored procedure. If you want to return a scalar value to the calling code use an OUTPUT parameter . RETURN is generally used for status codes .

You might have something like

-- SAMPLE UDF
CREATE FUNCTION dbo.YourUDF (@Username VARCHAR(30), @EntityID INT)
RETURNS INT 
AS
BEGIN
    RETURN @EntityID;
END
GO
-- SAMPLE PROCEDURE
CREATE PROCEDURE dbo.YourProc @Username VARCHAR(30), @EntityID INT, @Output INT OUTPUT
AS
BEGIN
    SET NOCOUNT ON;

    SET @Output = dbo.YourUDF(@Username, @EntityID);

    IF @Output IS NULL -- AN ERROR
    BEGIN
        RETURN 1; -- RETURN A STATUS OF -1 TO INDICATE ERROR
    END 

END

Then you could call this as:

DECLARE @Output INT, @ReturnValue INT;

EXECUTE @ReturnValue = dbo.YourProc 
                            @Username = '1234', 
                            @EntityID = 1, 
                            @Output = @Output OUTPUT;

SELECT  ValueFromUDF = @Output,
        ReturnValue = @ReturnValue;

This returns:

ValueFromUDF    ReturnValue
------------------------------
    1               0

If we pass NULL as @EntityID, to trigger the artificial error, then we get a return status of -1:

DECLARE @Output INT, @ReturnValue INT;

EXECUTE @ReturnValue = dbo.YourProc 
                            @Username = '1234', 
                            @EntityID = NULL, 
                            @Output = @Output OUTPUT;

SELECT  ValueFromUDF = @Output,
        ReturnValue = @ReturnValue;

ValueFromUDF    ReturnValue
------------------------------
    NULL            1