使用Applescript的浏览器自动化

Question

I have just started working with applescript and am trying web automation. My task is to launch the browser, sign in and then click on certain links.

While my script is able to launch browser and sign in, I am not able to automate the mouse click on links or buttons. I have tried a number of solutions available on the web(including those on stackoverflow) but nothing seems to work. The error message I am getting is 'value missing'

Since I am a completely new at applescript, I am not completely sure whether this can be done or not. Have a look at my script: (The comments "(*or: *)" are the alternates I have tried).

    set userID to "username"
    set pwd to "password"

    tell application "Safari"
    activate

    make new document with properties {URL:"http://example.com"}  (*or:         
    open location "example.com"*)

    tell application "System Events"
    delay 4
    keystroke tab

    keystroke userID
    delay 1
    keystroke tab

    keystroke pwd
    delay 1
    keystroke return
    delay 3

    tell application "Safari"  
   (*or: tell application "Safari" to tell active tab of window 1*)

    do JavaScript "$( 'apps-button .switcher-button switcher-button-   
    left :equ(0)').click()" in front document
    (*or: do JavaScript "document.getElementByID('apps-  
     button').click()"*)

    end tell
    end tell
    end tell

Answer 1

Although you'll have to heavily customize this for your situation, this is the code I'm using to log into AT&T's website and retrieve data usage information, then log out. The crucial part here is the wait() function. This is much better and more reliable than arbitrary delays. It checks for the status of Safari's reload button, and continues when it indicates the webpage is done loading. You can use Safari's web inspector to get element IDs and stuff. If you need any further help making this work, don't hesitate to ask!

set username to "username"
set _password to "password"

tell application "Safari"
    set new_document to make new document with properties {URL:"https://www.att.com/olam/loginAction.olamexecute"}
    tell me to wait()
    tell tab 1 of window 1
        do JavaScript "document.getElementById('userID').value = \"" & username & "\""
        do JavaScript "document.getElementById('password').value = \"" & _password & "\""
        do JavaScript "document.getElementById('LoginButton').children[0].click()"
        tell me to wait()
        set URL to "https://www.att.com/olam/displayUsageLanding.myworld?reportActionEvent=A_UMD_CURRENT_USAGE_SUMMARY"
        tell me to wait()
        display alert (do JavaScript "document.getElementById('WebUsage1').children[0].children[0].innerHTML")
        do JavaScript "document.getElementById('ge5p_z2-user-auth').click()"
        tell me to wait()
    end tell
    close window 1
end tell

on wait()
    delay 1
    tell application "System Events"
        tell application process "Safari"
            set shouldExitRepeat to false
            repeat
                try
                    repeat with curButton in (buttons of text field 1 of group 2 of toolbar 1 of window 1)
                        if name of curButton is equal to "reload" then
                            set shouldExitRepeat to true
                        end if
                    end repeat
                    if shouldExitRepeat then
                        exit repeat
                    end if
                end try
                delay 1
            end repeat
        end tell
    end tell
end wait