perl替换字符串中的字符，但保留特殊字符或空格

Question

I would like to create a program that replaces characters and retains the special characters. An example input and output is shown below.

Here's what I did so far:

$sentence = userinput;

@words = split(/ /, $sentence);

for ($i = 0; $i < @words.length; $i ++){
    $words[$i] =~ s/\W//g;
    @characters = split(//, $words[$i]);
    #print $words[$i] . "\n";

    $wordlength = length($words[$i]);


    for ($j = 0; $j < @characters.length; $j ++){

    $char = $characters[$j];

    for ($x = 0; $x < $wordlength; $x++){
        $char++;
        if ($char eq "aa"){
            $char = "a";
        }
        elsif ($char eq "AA"){
            $char = "A";
        }
    }
    print $char;
    if ($x = 0){
        $output[$i] = $char;
    }
    else {
        $output[$i] = join ($char);
    }
}

print $output[$i];
}

Input:

Hi! how are you doing?

Output:

Jk! krz duh brx itnsl?

Answer 1

A couple of things in your code don't make sense:

• Missing use strict; use warnings; use strict; use warnings; .
• All variables are global (you should be using my to create variables)
• @foo.length is not the number of elements in the array @foo . It's the number of elements in the array @foo concatenated with the number of characters in $_ (because arrays in scalar context return their length, . concatenates strings, and length works on $_ by default).
• join ($char) always returns the empty string: You're joining an empty list (no elements) using $char as a separator.

Here's an attempt to fix all of these issues:

use strict;
use warnings;

my $sentence = readline;

$sentence =~ s{([A-Za-z]+)}{
    my $word = $1;
    join '', map {
        my $base = ord(/^[A-Z]/ ? 'A' : 'a');
        chr((ord($_) - $base + length($word)) % 26 + $base)
    } split //, $word
}eg;

print $sentence;

Answer 2

I think what you are doing is rot3 encoding, but if so then your example is wrong

my $sentence = 'Hi! how are you doing?';
$sentence =~ tr/A-Za-z/D-ZA-Cd-za-c/;
print $sentence, "\n";

output

Kl! krz duh brx grlqj?

which is similar, but not identical to

Jk! krz duh brx itnsl?