使用VBA在EXCEL中搜索特定单词

Question

Im a beginner with Excel VBA my question is if I have string in a cell like "MyNameIsHammadAndImFromIreland" . All cells have strings/sentences but there is no spaces. How can I find if the cell includes the word "Ireland" ?

Answer 1

You don't need VBA, just use a formula:

=IF(LEN(SUBSTITUTE(A1,"Ireland",""))<LEN(A1),"Word Found","Word NOT found")  

---

If you really want VBA then:

hasWord = InStr(Range("A1").Value, "Ireland") > 0 '// returns TRUE or FALSE

Answer 2

The following VBA code will iterate through the used cells in a given worksheet and find any that match the given criteria. At the end, a message box is displayed showing a list of cells that contain the search term.

This functionality is equivalent to using the 'Find All' option you can choose when you use the normal find functionality available by pressing CTRL + F .

Option Explicit

Private Sub Find()

        Dim rngResult As Range
        Dim strToFind As String

        'Set to your desired string to find
        strToFind = "Ireland"

        'If the string you are searching for is located in
        'the worksheet somewhere, you can set the value
        'like this:  strToFind = Worksheets("Sheet1").Range("A1").Value
        'This assumes your search term is in cell A1 of the
        'Sheet1 worksheet.

        'Look in the used range of a given worksheet
        'Change Sheet1 to match your worksheet name
        With Worksheets("Sheet1").UsedRange

                'Find the first cell that contains the search term
                Set rngResult = .Find(What:=strToFind, LookAt:=xlPart)

                'If it is found, grab the cell address of where the
                'search term can be found
                If Not rngResult Is Nothing Then
                        Dim firstAddress As String, result As String
                        firstAddress = rngResult.Address

                'Loop through the rest of the cells until returning
                'to the first cell that we had a match in.
                Do
                        'Record the cell address of the match
                        'to the result string
                        result = result & rngResult.Address & ","

                        'Go to next cell containing the search term
                        Set rngResult = .FindNext(rngResult)

                'Exit the loop when we reach the starting point
                Loop While rngResult.Address <> firstAddress

                'Output the list of cells that contain the string to find
                MsgBox "Found """ & strToFind & """ in cell(s): " & result

                End If
        End With

End Sub

Be sure to set strToFind to your desired string, and change Sheet1 to match the name of whichever sheet you want to search over.