在Perl中捕获内联Java错误

Question

In this little perl script using inline saxon XSLT parser:

use Inline::Java;
use warnings;
use XML::Saxon::XSLT2;
open(my $xslt, '<:encoding(UTF-8)', $xslfile) or die $!;
open(my $xml, '<:encoding(UTF-8)', $xmlfile) or die $!;
my $trans  = XML::Saxon::XSLT2->new($xslt);
my $output = $trans->transform($xml);
print $output;

I would like to catch the transformation errors from saxon. Starting the script from the commandline, errors are written to STDERR. But how can I redirect the error message to a file inside the perl script? I tried Tie::STDERR which doesn't work.

I tried to redirect STDERR with

 open my $log_fh, '>>', '/tmp/the-log-file';
 *STDERR = $log_fh;

Then the perl errors are logged in /tmp/the-log-file, but not the saxon errors.

Answer 1

You should be able to do that with Capture::Tiny , which can grab the STDOUT and STDERR from external programs and XS.

use strict;
use warnings;
use XML::Saxon::XSLT2;
use Capture::Tiny 'capture';

my ($xslfile, $xmlfile) = ( ... ); 

open(my $xslt, '<:encoding(UTF-8)', $xslfile) or die $!;
open(my $xml, '<:encoding(UTF-8)', $xmlfile) or die $!;

my $trans  = XML::Saxon::XSLT2->new($xslt);
my $output;
my ( $stdout, $stderr ) = capture {
  $output = $trans->transform($xml);
};

print $output;

Please note I did not test this. Also I don't see where you need the Inline::Java.

Answer 2

The JVM has its own notion of standard error that is not easily manipulated from Perl. To do what you want to do I think you have to reset STDERR before the JVM starts up. That will require a BEGIN block that appears before your use Inline Java statement.

Proof of concept:

# javaerr.pl
BEGIN {
    open OLDERR, '>&STDERR'; # save orig STDERR
    open STDERR, '>', 'foo'; # redirect before JVM starts
}

use Inline Java => <<'END_OF_JAVA_CODE';
public class Foo {
  static { 
    System.err.println("loaded Foo static block");
  }

  public Foo() {
  }

  public void warn(String msg) {
    System.err.println("Foo warning: " + msg);
  }
}
END_OF_JAVA_CODE

*STDERR = *OLDERR;        # restore orig STDERR
open STDERR, '>', 'bar';  # or direct it somewhere else

$Foo = Foo->new();
$Foo->warn("hello world");

print STDERR "goodbye\n";

--

$ perl javaerr.pl
$ cat foo
loaded Foo static block
Foo warning: hello world
$ cat bar
goodbye