通过登录的VBS脚本用户帐户描述

Question

I have a fairly common VBScript to update user object descriptions in ADUC with the computer name, IP, and date/time of their last logon. I've got that functioning properly in my environment. I've been trying to figure out how to add a "if contains then" statement to look at the distinguished name of the computer object, if it contains my server organizational unit name in the string, then quit the script. I've tried it a few ways and can't seem to figure it out. We use a lot of terminal servers for different applications and so my intent is to only update descriptions when logon occurs on a PC. I've found so many examples of scripts that serve similar functions, at this point I'm completely lost. I'm sure this has been done before but I'm not being able to find the right path.

'Open a connection to LDAP
Set objSysInfo = CreateObject("ADSystemInfo")
'Find the User in LDAP that is opening the connection
Set objUser = GetObject("LDAP://" & objSysInfo.UserName)
'Find the Computer in LDAP that the connection originates from
Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName)
'Set string to local computer
strComputer = "." 
'If object contains value of being in the server OU, quit the script.

'!-This is the section I'm trying to figure out, removed my failed attempts-!

'impersonate the computer's wmiservice
Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
'Use the wmiservice to query for the IPAddresses from the Network Adapter Configuration where the NIC is IPEnabled
Set IPs = objWMIService.ExecQuery _ 
 ("Select IpAddress from Win32_networkadapterconfiguration where IPEnabled = True") 
'For Each IPAddress returned, set string to the IPAddress (Hopefully the IPv4 one)
For Each IP in IPs
 strIPaddr = IP.IPAddress(i)
'Loop through
Next
'Build the string that will bound to the User's Description
' In this case: Workstation001 - 192.168.100.21 - 3/6/2015 12:51PM
strMessage = objComputer.CN & " - " & strIPaddr & " - " & Now 
'Apply the string to the User's Description, then write it to LDAP
objUser.Description = strMessage
objUser.SetInfo

Maybe the better way to attack this is to filter by operating system? I thought when you performed the GetObject with objSysInfo.ComputerName it would come back with the distinguished name to do the if contain then. Maybe my understanding is wrong.

Update1: Thanks to JosefZ I figured it out. Full script below:

Set objSysInfo = CreateObject("ADSystemInfo")
Set objUser = GetObject("LDAP://" & objSysInfo.UserName)
Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName)
If InStr(1, objComputer.distinguishedName, "SERVERS") > 0 then
 Wscript.Quit
End if
strComputer = "." 
Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
Set IPs = objWMIService.ExecQuery _ 
 ("Select IpAddress from Win32_networkadapterconfiguration where IPEnabled = True") 
For Each IP in IPs
 strIPaddr = IP.IPAddress(i)
Next
strMessage = objComputer.CN & " - " & strIPaddr & " - " & Now 
objUser.Description = strMessage
objUser.SetInfo

On line 4 change "SERVERS" to something that exists in the name of the OU you want to exclude from this script. I wanted to stop this script from running when users logged into servers and "SERVERS" is part of the title of the Parent OU. When it finds that string it will quit the script.

Answer 1

Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName)
If InStr(1, objComputer.distinguishedName, "SERVERS") > 0 then
 Wscript.Quit
End if

Full script in "Update 1" of question.