打开弹出消息窗口的编辑工作表

Question

I'm using the following macro to open a popup message box pulling in specific cell values. When the message box is open I can't edit the worksheet. When I move my mouse pointer off the message box it turns to a spinning circle. How do I open my message box, have it stay open and edit the worksheet underneath?

Sub PopUp()
    Dim vMsg
    Dim r As Integer
    For r = 4 To 16
    vMsg = vMsg & Range("AD" & r).Value & Range("AE" & r).Value & Range("AF" & r).Value & Range("AG" & r).Value & Range("AH" & r).Value & Range("AI" & r).Value & Range("AJ" & r).Value & vbCrLf
    Next
    MsgBox vMsg, , "Values"
End Sub 

Answer 1

The built in MsgBox is modal, which means you cannot manipulate the worksheet until the user dismisses, in some fashion, the message box. The typical workaround appears to be to create your own custom UserForm to display the message and call it with UserForm1.Show vbModeless , which will display the message and allow the user to still edit the worksheet.

However, there is an alternative way than creating your own custom UserForm . You can use the Windows API instead of the VBA interface.

To do this, start by adding this code to the top of your module (before all subroutines and functions):

Private Declare Function MessageBox _
    Lib "User32" Alias "MessageBoxA" _
       (ByVal hWnd As Long, _
        ByVal lpText As String, _
        ByVal lpCaption As String, _
        ByVal wType As Long) _
    As Long

The syntax above takes the Windows API function MessageBoxA and allows you to call it by calling MessageBox (it is aliased).

You can then update your PopUp subroutine to use the new MessageBox function.

Sub PopUp()
    Dim vMsg
    Dim r As Integer
    For r = 4 To 16
    vMsg = vMsg & Range("AD" & r).Value & Range("AE" & r).Value & Range("AF" & r).Value & Range("AG" & r).Value & Range("AH" & r).Value & Range("AI" & r).Value & Range("AJ" & r).Value & vbCrLf
    Next
    MessageBox &H0, vMsg, "Values", vbOkayOnly
End Sub 

This will allow the user to access the sheet while the message box is displayed. Additionally, the line:

MessageBox &H0, vMsg, "Values", vbOkayOnly

Can be changed to

MessageBox &H0, vMsg, "Values", vbSystemModal

This will allow you to access the sheet, but will keep the message box on top at all times (it will do this for all applications, not just Excel, but nothing is perfect).

The MessageBox function takes in four parameters:

• hWnd is the special identifier of the window which owns this message box, the trick is to pass in a null with &H0 so that no window owns it
• lpText is the message to be displayed (same as the prompt parameter of the VBA MsgBox function)
• lpCaption is the text to be displayed as the title (same as the title parameter of the VBA MsgBox function)
• wType is the type of message box that will be displayed (identical to the buttons parameter of the VBA MsgBox function)

You can read more here .

Answer 2

Unfortunately, Message boxes are Modal - so they will take the focus until they are dismissed.

The way around this is to create a custom userform which you can use as a messagebox. There is an option on userforms to make them non-modal - which will allow you to carry on with other actions, while they are open.

I hope that this helps