如何将特定文件夹的每个子文件夹中的所有 *.pdf 文件移动到每月创建的子文件夹？

Question

I have been attempting to create a single batch file that will do monthly work for me with files throughout various folders.

Currently the folder C:\\test\\WSP\\ has numerous other folders (account names) with PDF's in them. We need to:

1. create a folder with MM-YYYY within C:\\test\\WSP\\{Account Name}\\
2. and move those PDF's into that new folder. So the end result being C:\\test\\WSP\\{Account Name}\\08-2015\\ with all new PDF's in there.
3. Then move onto the next directory C:\\test\\WSP\\{Account Name2} ,
4. create the 08-2015 folder and move all the PDFs into C:\\test\\WSP\\{Account Name2}\\08-2015 so on and so forth.

I can do process as needed within each {Account Name} folder by placing a batch file containing:

@ECHO OFF
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
set MONTH="%month%"
set YEAR ="%year%""
md %YEAR%\%MONTH%
MOVE *.pdf %YEAR%\%MONTH%\

And running every month in each folder, however, there are over 200 folders here.

Is there anyway to comb through each folder, create the directory and move the PDF's into the new folder, then move onto the next directory?

Answer 1

Use for /d to enumerate the folders:

@echo off
for /f "tokens=2-4 delims=/.- " %%a in ('date /T') do set "year=%%c" & set "month=%%a"
set newdir=%MONTH%-%YEAR%

for /d %%d in ("C:\test\WSP\*") do (
    md "%%d\%newdir%\\"
    MOVE "%%d\*.pdf" "%%d\%newdir%\\"
)
pause

Answer 2

Here is a commented batch code for this task:

@echo off

rem Get month and year from environment variable DATE. The
rem date format depends on region and language settings for
rem the current user. The code below expects the date in
rem format DD.MM.YYYY or DD/MM/YYYY without or with weekday
rem at beginning which is the reason why referencing the
rem characters to copy from date string is done from end of
rem the string instead of beginning. Run in a command prompt
rem window echo %DATE% to see the date format of your user
rem account.

set "MonthFolder=%DATE:~-7,2%-%DATE:~-4%"

rem Use command FOR to process each non hidden and non
rem system subdirectory of specified parent directory. The
rem loop variable D holds the name of the found subdirectory
rem with complete path.

rem If the subdirectory contains 1 or more files with the
rem file extension PDF, a subdirectory with month any year
rem is created in current subdirectory in case of not already
rem existing and all PDF files are moved into this monthly
rem created subdirectory.

for /D %%D in ("C:\test\WSP\*") do (
    if exist "%%D\*.pdf" (
        if not exist "%%D\%MonthFolder%\*" md "%%D\%MonthFolder%"
        move /Y "%%D\*.pdf" "%%D\%MonthFolder%\" >nul
    )
)

set "MonthFolder="

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• echo /?
• for /?
• if /?
• md /?
• move /?
• rem /?
• set /?

And see also the Microsoft article about Using command redirection operators for an explanation of >nul which redirects the information output by command MOVE about moved files to device NUL to suppress this information.