使用AWK将格式HH：MM：SS转换为秒

Question

i have a table

RMA###Order###FR2345###00:56:10###AK234
FWA###working###FR1345###00:30:20###DE432
HQP###cat1###FR6798###1:00:20:40###TI685

i need replace the field DD:HH:MM:SS to seconds

RMA###Order###FR2345###3370###AK234
FWA###working###FR1345###1820###DE432
HQP###cat1###FR6798###87640###TI685

the table is separate by '###' but the field is by ':'

i ussing

echo "1:00:20:40" | awk -F: '{ print ($1 * 86400)+($2 * 3600) + ($3 * 60) + $4 }'
87640

to convert

and to separate the table

awk  -F, 'BEGIN {FS=OFS="###"}

but how separate the field by ':' and convert to seconds in the same script?

Answer 1

If you put this into a.awk

BEGIN {
    OFS = FS = "###"
}
{
    b = split($4,a,":")
    if (b == 4) {
      print $1, $2, $3, (a[1] * 86400)+(a[2] * 3600) + (a[3] * 60) + a[4], $5   
    } else {
      print $1, $2, $3, (a[1] *3600) + (a[2] * 60) + a[3], $5
    }
}

And then run

awk -f a.awk foo.txt

You will get the desired output:

RMA###Order###FR2345###3370###AK234
FWA###working###FR1345###1820###DE432
HQP###cat1###FR6798###87640###TI685

Answer 2

You can use the split function:

awk '{ split($0,a,":"); print (a[1]*86400)+(a[2]*3600)+(a[3]*60)+a[4] }' <<< '1:00:20:40'
87640

So you don't mess with FS

Answer 3

I propose this solution,

awk 'BEGIN {
  FS=OFS="###";
  split("1 60 3600 86400", vconv, " ");
}
{
  n=split($4,vtime,":")
  seconds = 0;
  for(i=1; i<=n; i++){
    seconds += vconv[i] * vtime[n-i+1];
  }
  $4 = seconds;
  print;
}' input

you get:

RMA###Order###FR2345###3370###AK234
FWA###working###FR1345###1820###DE432
HQP###cat1###FR6798###87640###TI685

Answer 4

another awk

$ awk 'BEGIN{FS=OFS="###"} 
            {n=split($4,t,":");
             s=0;
             if(n==4)s=24*t[1]; 
             s=((s+t[n-2])*60+t[n-1])*60+t[n]; $4=s}1' file 

RMA###Order###FR2345###3370###AK234
FWA###working###FR1345###1820###DE432
HQP###cat1###FR6798###87640###TI685

Answer 5

[root@test /tmp]$ awk 'BEGIN {FS=OFS="###"}{s=split($4,t,":");$4=t[s]+t[s-1]*60+t[s-2]*3600+t[s-3]*86400}1' file.txt

RMA###Order###FR2345###3370###AK234
FWA###working###FR1345###1820###DE432
HQP###cat1###FR6798###87640###TI685