在 SQL 存储过程中分配 @@RowCount 的正确位置

Question

I am looking for the correct spot to set my @RecordCount = @@ROWCOUNT; Is it possible to just set it once or is it necessary to set it after each query?

My stored procedure is as follows:

BEGIN
SET NOCOUNT ON;


SELECT *
FROM Table1
WHERE Status = 'A'
AND college = @icollege
AND DeptCode = @idept
AND MajorCode = @imajr;

IF @@ROWCOUNT = 0
BEGIN
    SELECT *
    FROM Table1
    WHERE Status = 'A'
    AND college = @icollege
    AND DeptCode = @idept
    AND MajorCode = '****';

    IF @@ROWCOUNT = 0
    BEGIN
        SELECT *
        FROM Table1
        WHERE Status = 'A'
        AND college = @icollege
        AND DeptCode = '****'
        AND MajorCode = '****';

        SET @RecordCount = @@ROWCOUNT;
    END 

    SET @RecordCount = @@ROWCOUNT;
END

SET @RecordCount = @@ROWCOUNT;
END

Answer 1

Every statement ¹ causes @@ROWCOUNT to be set. This means that if you want to do multiple things with the value set by one statement, you need to capture the value immediately into another variable.

So, I'd do something like:

BEGIN
SET NOCOUNT ON;

SELECT *
FROM Table1
WHERE Status = 'A'
AND college = @icollege
AND DeptCode = @idept
AND MajorCode = @imajr;

SET @RecordCount = @@ROWCOUNT;
IF @RecordCount > 0 RETURN

SELECT *
FROM Table1
WHERE Status = 'A'
AND college = @icollege
AND DeptCode = @idept
AND MajorCode = '****';

SET @RecordCount = @@ROWCOUNT;
IF @RecordCount > 0 RETURN

SELECT *
FROM Table1
WHERE Status = 'A'
AND college = @icollege
AND DeptCode = '****'
AND MajorCode = '****';

SET @RecordCount = @@ROWCOUNT;

END

I would, though, also note that this stored procedure may produce up to 3 result sets (with the first 1 or 2 being empty). If your calling code doesn't want to deal with that then we may need to come up with a single query that applies all of the criteria, and selects for the best matches.

---

¹ I'm probably wrong here and there's some obscure statement or set of statements that do not. But as a general rule and for most common statements, DML, control flow, SET , etc, it's true.