将CSV文件转换为txt文件

Question

I'm using perl to convert a comma separated file to a tab separated file with this command:

perl -e ' $sep=","; while(<>) { s/\Q$sep\E/\t/g; print $_; } warn "Changed $sep to tab on $. lines\n" ' csvfile.csv > tabfile.tab

However, my file has additional commas that I do not want to be separated in specific columns. Here's and example of my file:

ADNP, "descript1, descript2", 1
PTB, "descriptA, descriptB", 5

I only want to convert the comma's outside of the quotations to tabs as so:

ADNP    descript1, descript2    1
PTB    descriptA, descriptB    5

Is there anyway to go about doing this with either perl, python, or bash?

Answer 1

Trivial in Perl, using Text::CSV :

#!/usr/bin/env perl
use strict;
use warnings;
use Text::CSV;

#configure our read format using the default separator of ","
my $input_csv = Text::CSV->new( { binary => 1 } );
#configure our output format with a tab as separator. 
my $output_csv = Text::CSV->new( { binary => 1, sep_char => "\t", eol => "\n" } );

#open input file
open my $input_fh, '<', "sample.csv" or die $!;
#iterate input file - reading in 'comma separated' 
#printing out (to stdout -can use filehandle) tab separated. 
while ( my $row = $input_csv->getline($input_fh) ) {
    $output_csv->print( \*STDOUT, $row );
}

Answer 2

In python

import csv

with open('input', 'rb') as inf:
    reader = csv.reader(inf)
    with open('output', 'wb') as out:
        writer = csv.writer(out, delimiter='\t')
        writer.writerows(reader)

Answer 3

You need regular expressions to help you. In python it would simply be:

>>> re.split(r'(?!\B"[^"]*),(?![^"]*"\B)',  'ADNP, "descript1, descript2", 1'
['ADNP', ' "descript1, descript2"', ' 1']

Answer 4

建立rll的regex答案，就可以像现在一样将其变成perl oneliner

perl -ne 'BEGIN{$,="\t";}@a=split(/(?!\B"[^"]*),(?![^"]*"\B)/);print @a' csvfile.csv > tabfile.tab

Answer 5

This'll work:

perl -e '$sep=","; while(<STDIN>) { @data = split(/(\Q$sep\E?\s*"[^"]+"\s*\Q$sep\E?)/); foreach(@data){if(/"/){s/^\Q$sep\E\s*"//;s/"\s*\Q$sep\E$//;}else{s/\Q$sep\E/\t/g;}}print(join("\t",@data));} warn "Changed $sep to tab on $. lines\n"' < csvfile.csv > tabfile.tab

Putting parens in the pattern to split, returns the captured separators along with the split elements and effectively separates the strings containing quotes into separate list elements that can be treated differently when quotes are detected. You just strip off the commas and quotes for the quoted strings and substitute for tabs in the other elements, then join the elements with tabs (so that the quoted strings get joined with tabs to the other already tabbed strings.

Answer 6

The Text::CSV module is what you're looking for. There are a lot of considerations when parsing CSV files, and you really don't want to handle all of them yourself.