如何在Hadoop的Apache Pig中基于两个子包构建超级包

Question

Suppose I have two bags, B1 and B2, and wondering how to make a super bag contain the two bags? The purpose I want to have one super bag containing two sub-bag is because I want to call UDF SetDifference of datafu, which seems to be called on a relation which contains two bags?

In my case, I already have two bags, B1 and B2. I think I need to assemble a super bag "input" in this sample.

http://datafu.incubator.apache.org/docs/datafu/guide/set-operations.html

differenced = FOREACH input {
  -- input bags must be sorted
  sorted_b1 = ORDER B1 by val;
  sorted_b2 = ORDER B2 by val;
  GENERATE SetDifference(sorted_b1,sorted_b2);
}

Update:

Here is my code and related error message, if anyone have any good ideas, it will be great.

register datafu-1.2.0.jar;
define setDifference datafu.pig.sets.SetDifference();

-- input1.txt: {(3),(4),(1),(2),(7),(5),(6)}
-- input2.txt: {(1),(3),(5),(12)}
A = load 'input1.txt' AS (B1:bag{T:tuple(val:int)});
B = load 'input2.txt' AS (B1:bag{T:tuple(val:int)});

sorted_b1 = ORDER A by val;
sorted_b2 = ORDER B by val;
differenced = setDifference(sorted_b1,sorted_b2);

-- expected produces: ({(2),(4),(6),(7)})
DUMP differenced;

[main] ERROR org.apache.pig.tools.grunt.Grunt - ERROR 1200: <file TestDataFu3.pig, line 11> Cannot expand macro 'setDifference'. Reason: Macro must be defined before expansion.

thanks in advance, Lin

Answer 1

Okay I see what you are asking; your bags are in different files. You will need to import and then join them so that they are in the same relation.

Script :

REGISTER /path/to/jars/datafu-1.2.0.jar;
DEFINE SetDifference datafu.pig.sets.SetDifference();

data1 = LOAD 'input1' AS (B1:bag{T1:tuple(val1:int)});
data2 = LOAD 'input2' AS (B2:bag{T2:tuple(val2:int)});
A = JOIN data1 BY 1, data2 BY 1;
diff = FOREACH A {
  S1 = ORDER B1 BY val1;
  S2 = ORDER B2 BY val2;
  GENERATE SetDifference(S1, S2);
};
DUMP A;

Output :

({(2),(4),(6),(7)})

Hope this helps.