VB.NET-关机计时器/睡眠标签

Question

I have the following code, which is supposed to load the form, change the text every second and then run a shutdown command at the end. The cancel button would cancel the shutdown (or just close the form, preventing the shutdown command from running).

Public Class FRM_SHUTDOWN

Private Sub FRM_SHUTDOWN_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    LBL_TIMER.Text = "Shutting Down in 6..."
End Sub

Private Sub FRM_SHUTDOWN_Shown(sender As Object, e As EventArgs) Handles Me.Shown
    LBL_TIMER.Text = "Shutting Down in 6..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Shutting Down in 5..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Shutting Down in 4..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Shutting Down in 3..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Shutting Down in 2..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Shutting Down in 1..."
    Threading.Thread.Sleep(1000)
    LBL_TIMER.Text = "Windows is Shutting Down"
    Threading.Thread.Sleep(1000)
    'System.Diagnostics.Process.Start("shutdown", "-s -t 0")
    MessageBox.Show("Shutdown instant would happen here")
End Sub

Private Sub BTN_CANCEL_Click(sender As Object, e As EventArgs) Handles BTN_CANCEL.Click
    'System.Diagnostics.Process.Start("shutdown", "-a")
    MessageBox.Show("Cancel shutdown command")
    Me.Close()
End Sub

End Class

The problem I'm having is that the form loads and appears like this:

So it doesn't actually show the 'stop' button or the countdown timer!

Can anyone explain why?

Answer 1

Your application is busy waiting, so it can't redraw the form (Adding LBL_TIMER.Refresh will help but is not the correct way to do this). You need to do your waiting in a thread that is separate from the UI thread.

The easiest way to do this is with a background worker. This handles some of the synchronisation between UI thread and the background thread for you.

Run the worker when the form loads and then do your waiting in the worker DoWork method.

You can report your progress back using the ReportProgress method

 Private WithEvents _worker As New BackgroundWorker With
    {.WorkerReportsProgress = True, .WorkerSupportsCancellation = True}
Private _cancelled As Boolean = False

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    _worker.RunWorkerAsync()
End Sub

Private Sub _worker_DoWork(sender As Object, e As DoWorkEventArgs) Handles _worker.DoWork
    _cancelled = False
    For i As Integer = 6 To 1 Step -1
        CType(sender, BackgroundWorker).ReportProgress(i)
        Threading.Thread.Sleep(1000)
        If CType(sender, BackgroundWorker).CancellationPending Then Exit Sub
    Next
End Sub

Private Sub _worker_ProgressChanged(sender As Object, e As ProgressChangedEventArgs) Handles _worker.ProgressChanged
    Label1.Text = "Shutting down in " & e.ProgressPercentage
End Sub

Private Sub _worker_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles _worker.RunWorkerCompleted
    If _cancelled Then
        MessageBox.Show("Shutdown was cancelled")
    Else
        MessageBox.Show("Shutdown instant would happen here")
    End If

End Sub

Private Sub btnCancel_Click(sender As Object, e As EventArgs) Handles btnCancel.Click
    _cancelled = True
    _worker.CancelAsync()
End Sub