如何在Delphi中跟踪点

Question

I'm struggling to find a way to be able to keep track of points. I'm coding a educational game for my high school 3rd term project and my educational game is a series of multiple choice word problems, what I want to happen is that every time the user clicks on the right answer a point should be added so that when the user reaches the end page and clicks on the 'get results' button that delphi would count up all of the correct answers the user has gotten and displays them in a pop-up message.

Answer 1

While solution that David Heffernan suggests in his comment is easiest to implement (before moving to next question you simply check if the user answered correctly and increase points if he did before moving to next question) I would rather go for solution recommended by paulsm4. Why?

His solution recommends storing all the answers user made which in the end gives you ability so that you can show the user which questions did he answer correctly and which not and which would be the correct answers.

Now since you are making an educational game showing the user where he screwed up and his answer should be will greatly improve value and usability of your application.

So how do you implement this:

First I would recommend creating a record for storing information regarding each question like so

RQuestion = record
  //Contains the text which represents the question
  QuestionText: String;
  //Contains text which represents first answer
  Answer1Text: String;
  //Contains text which represents second answer
  Answer2Text: String;
  //Contains text which represents third answer
  Answer3Text: String;
  //Contains text which represents fourth answer
  Answer4Text: String;
  //Simple integer value to store which is the correct answer
  CorrectAnswer: Integer;
  //Simple integer value to store which answer was chosen by the user
  SelectedAnswer: Integer;
end;

Then in order to store required data for all questions you can simply make an array of RQuestion typed items

ArrQuestions: Array[0..NumOfQuestions] of RQuestion;

So now you are able to access data regarding each question like this:

var Questions: ArrQuestions;

...

//Text of the question
QText := Questions[QNum].QuestionText;
//Text of the first answer
A1Text := Questions[Qnum].Answer1Text;
//Text of the second answer
A2Text := Questions[Qnum].Answer2Text;
//Text of the third answer
A3Text := Questions[Qnum].Answer3Text;
//Text of the fourth answer
A4Text := Questions[Qnum].Answer4Text;
//Correct answer
CorrAnsw := Questions[Qnum].CorrectAnswer;
//Chosen answer
SelAnsw := Questions[QNum].SelectedAnswer;

Then in order to calculate the number of points your user has accumulated you simply loop through the array of questions and check if the user answered correctly to them

TotalPoints := 0;
for Qnum := 0 to NumOfQuestions do
begin
  if Questions[QNum].CorrectAnswer = Questions[QNum].SelectedAnswer then
    TotalPoints := TotalPoints+1;
end;

Now as I said before in the end you can give your user ability to review his answers and see which ones did he chose and which ones are the correct ones.

This way you improve the learning ability of your users.

---

Bonus content

When you are using records and arrays of records in your program you gain the ability to quickly load the information in these records from a file by using of typed files.

//Assign file handle
AssignFile(QFile,'D:\Questions.dat');
//Open file in read only mode
Reset(QFile);
//Set the desired question umber that you want to read
QNume := 10;
//Move file position to the specific question
//Exact position in bytes is automatically calculated
//since we are using typed files
Seek(QFile,QNum);
//Read the data from file into specific variable which can
//Also be a record inside an array
Read(QFile,Questions[QNum]);
//Close the file handle when you are done
CloseFile(QFile);

However you should note that in order to do so your record types needs to be of fixed size. This means that every field/variable inside your record needs to have fixed size.

Unfortunately in case of strings this is not so since in Delphi strings are actually referenced types and their size actually depends on the text that is stored in such string.

So if you would want to gain the ability to load such records directly from a typed file you would have to change all of the strings into short strings

RQuestion = record
  //Contains the text which represents the question
  QuestionText: ShortString;
  //Contains text which represents first answer
  Answer1Text: ShortString;
  //Contains text which represents second answer
  Answer2Text: ShortString;
  //Contains text which represents third answer
  Answer3Text: ShortString;
  //Contains text which represents fourth answer
  Answer4Text: ShortString;
  //Simple integer value to store which is the correct answer
  CorrectAnswer: Integer;
  //Simple integer value to store which answer was chosen by the user
  SelectedAnswer: Integer;
end;

Now the only problem is that ShortStrings only support ANSI based characters. So you may lose the ability to use some of the NON US characters in text.

In case if you need to have UNICODE strings you would have to use a bit different approach. In such approach you won't be storing the text inside the records but instead separately in a StringList . And your records would simply store the index information about specific StringList entry that contains text specific to your question/answer

So the question record would now look like this

RQuestion = record
  //Contains StringList index at which the question text is stored
  QuestionText: Integer;
  //Contains StringList index at which the first answer text is stored
  Answer1Text: Integer;
  //Contains StringList index at which the second answer text is stored
  Answer2Text: Integer;
  //Contains StringList index at which the third answer text is stored
  Answer3Text: Integer;
  //Contains StringList index at which the fourth answer text is stored
  Answer4Text: Integer;
  //Simple integer value to store which is the correct answer
  CorrectAnswer: Integer;
  //Simple integer value to store which answer was chosen by the user
  SelectedAnswer: Integer;
end;

So now you have fixed sized records which can be easily loaded or saved from typed files. And you can easily load or save questions and answers texts into or from StringList by using String Lists LoadFromfile or SaveToFile methods.

And the best thing about this last approach is that you can even have multiple text files where each text file contains text written in different language which gives you easy way to design multiligual tests with your application.