正则表达式以匹配日月和年

Question

I'm tried a bit with Windows date format which relays on regional settings. Therefore to match day, month and year I started to use regex. I have some very basic experience in it, I used regex in Python.

My date format is dd/mm/yyyy hh:mm:ss

To match day, month and year I have this pattern:

Dim strPattern As String: strPattern = "(\d+\d+)/(\d+\d+)/(\d+\d+\d+\d+)"

and I suppose that when my input is:

currDate = 13/11/2014 08:36:00

then in this code:

Set allMatches = regEx.Execute(currDate)
matchesNo = allMatches.Count
If matchesNo <> 0 Then
    result = allMatches.Item(0).SubMatches.Item(0)
End If

I would expect that variable matchesNo will have value 3 . Unfortunately it has value 1 .

Question is, why?

Answer 1

Capturing groups do not yield matches, but submatches. You have 1 match, and 3 submatches since you have 3 capturing groups. And as for the regex, you may use limiting quantifier {num} , and word boundaries \\b :

(\d{2})/(\d{2})/(\d{4})\b

The \\d{2} means match a digit exactly 2 times . \\b will ensure a whole word match.

Here is an example that prints all the date details obtained from the strings containing datetime values in your format:

Sub GetDdMmYyyyDateDetails()
Dim rExp As Object, allMatches As Object, match As Object
Dim currDate As String, day As String, month As String, year As String

currDate = "13/11/2014 08:36:00 some more 24/12/2015 01:35:55"

Set rExp = CreateObject("vbscript.regexp")
With rExp
    .Global = True
    .MultiLine = False
    .pattern = "\b(\d{2})/(\d{2})/(\d{4})\b"
End With


Set allMatches = rExp.Execute(currDate)
For Each match In allMatches
    day = match.SubMatches.Item(0)
    month = match.SubMatches.Item(1)
    year = match.SubMatches.Item(2)
    Debug.Print "Day: " & day & vbCrLf; "Month: " & month & vbCrLf & "Year: " & year
Next

End Sub

This will print

Day: 13
Month: 11
Year: 2014
Day: 24
Month: 12
Year: 2015