使用 .bat 批处理文件从文件名中删除字符串

Question

I have a folder with thousands of filenames like this. I need to put them inside folders and remove the useless parts from the filenames. I need to do this before adding the files inside my XBMC library.

[ www.AnnoyingSpam.com ] Some.File.Name.With.A.Very.Long.String.avi
[ www.AnnoyingSpam.com ] Another.File.With.A.Very.Long.String.mpg
[ www.AnnoyingSpam.com ] Again.And.Again.mp4

• First, I want to strip the AnnoyingSpam.com tags in the files
• Then, create a folder based on the file name without the tag and without the extension
• Finally, move the file to the new folder
• Repeat for the rest of the files in the root directory of the batch file

So far all I got is a script that will create folder and move files. But it adds the tag "Folder" to each folder and it doesn't remove the AnnoyingSpam.com tag

@echo off

for /f "usebackq delims=?" %%a in (`dir /a-d /b`) do (
  if not "%%~dpnxa"=="%~dpnx0" call :func "%%~a"
)

goto :EOF

:func
set file=%~1
set dir=%file% Folder
md "%dir%" Folder 2>nul
move "%file%" "%dir%" 
goto :EOF

So my question is how can i remove these strings from the folder names that are being created in the above script:

"[ www.AnnoyingSpam.com ]"

" Folder"

Answer 1

Since you are performing the check if not "%%~dpnxa"=="%~dpnx0" call :func "%%~a" , my understanding is that you will be running the batch from inside the 'target' folder.

What follows is a batch script, based structurally on your sample, that accomplishes the necessary filtering and handles the rename and move operations.

@echo off

setlocal ENABLEDELAYEDEXPANSION
for /f "usebackq delims=?" %%a in (`dir /a-d /b`) do (
    if not "%%~dpnxa"=="%~dpnx0" call :func "%%~a"
)
endlocal

echo Done.
goto EOF

:func
set file=%~1

for /F "delims=" %%a in ("!file!") do (
    rem stripped extension, next step is to filter to remove the 'spam' part
    set "c=%%~Na"
    rem original filename, will be needed for the renaming
    set "o=%%~a"
    rem store the extension to use later on when re-constructing the filename
    set "e=%%~xa"
    rem this is effectively a multichar stripper; filters the 'spam' part out
    set "c=!c:[ www.AnnoyingSpam.com ] =!"
    rem reconstruct the filename
    set "f=!c!!e!"
    rem echo !o! : !c! : !e! ::: !f!
    rem rename original file to the filtered version
    ren "!o!" "!f!"
    rem create dir named after the filtered filename, if it does not already exist; just a precaution
    if not exist !c! (md !c!)
    rem move the filtered file to the appropriate dir
    move "!f!" "!c!" > nul
)

:EOF

---

The script is almost self-explanatory (see the comments inside), however there are some aspects that I would like to point out:

• The instructions setlocal ENABLEDELAYEDEXPANSION and endlocal , that in fact form a wrap around the for-loop , establish that the variables inside the loop will be evaluated (expanded) at the execution time and not during parse time. Notice that the variables are referenced inside the loop as !var! . See more on this here .

• The removal of the unwanted 'spam' part is performed by this command: set "c=!c:[ www.AnnoyingSpam.com ] =!" . What it does is best described by the following example: set "var=!var:substring1=substring2!" , has as a result the substitution of every occurrence of substring1 by substring2 in var . If substring2 is null (as is the case here), then the actual effect is the removal of every substring1 pattern found in the original variable. More on this here , and for an interesting use as a multichar delimiter see dbenham's answer here .

And, as always, test thoroughly before you use the script on the actual folders.

Answer 2

I know you've asked for a batch script, but if you have php installed, you can use this:

renameSpam.php

<?php

$removeTag = "[ www.AnnoyingSpam.com ]";

foreach(glob("*.*") as $file){

    if (strpos($file, $removeTag) !== false) {
        $newFile = trim(str_ireplace($removeTag, "", $file));
        $ext = pathinfo($newFile, PATHINFO_EXTENSION);
        $fnNoExt = basename($newFile,".".$ext);

        if(!is_dir($fnNoExt)){
            mkdir($fnNoExt, 0777);
            rename($file, "./$fnNoExt/$newFile");
        }else{
            rename($file, "./$fnNoExt/$newFile");
        }

    }
}

---

Place renameSpam.php on the directory with the files to rename and execute as php renameSpam.php .
I've tested this on windows and linux and it works as intended.