将一种样式的最后一段转换为另一种样式，ms字，VBA

Question

This code allows to change all text with style "myStyleOne" for "myStyleTwo".

Option Explicit
Sub replaceStyleForAnotherStyle()
Selection.Find.ClearFormatting
Selection.Find.Style = ActiveDocument.Styles("myStyleOne")
Selection.Find.Replacement.ClearFormatting
Selection.Find.Replacement.Style = ActiveDocument.Styles("myStyleTwo")
With Selection.Find
    .Text = ""
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

What should the code look like if I want to turn only the last paragraph of "myStyleOne" into "myStyleTwo"?

Answer 1

To find the last paragraph with a given style:

Function lastOfStyle(st As String) As Paragraph
    For i = ActiveDocument.Paragraphs.Count To 1 Step -1
        If ActiveDocument.Paragraphs(i).Style = st Then
            Set lastOfStyle = ActiveDocument.Paragraphs(i)
            Exit Function
        End If
    Next
End Function

Now you can change the style with this simple statement:

lastOfStyle("MyStyle1").Style = "MyStyle2"

But if you want to do it in your macro, for other reasons that I missed, then you should add the following at the beginning of your macro:

Dim p as Paragraph: Set p = lastOfStyle("Normal")
if p Is Nothing then Exit Sub
p.Range.Select

Then set .Wrap = wdFindStop in the With Selection.Find bloc instead of * .Wrap = wdFindContinue *

Answer 2

Have you seen this answer? It really helps: answer . The things you might know: in VBA there are subroutines (sub) and functions. Functions can be used in many subroutines and should go separately.

Great. You want to copy and use the code? Here you are, just copy it all to the developer tab on the ribbon: http://codepad.org/Wd5Rer4y . Then you can run sub replaceStyleForAnotherStyleSimple() or sub replaceStyleForAnotherStyleComplicated() . Both of them rely on function lastOfStyle . Click alt+f8 and choose wisely.

Great. But is it possible to do the same thing without function? Sure! Here it comes! replaceStyleForAnotherStyleNoFunction()

Sub replaceStyleForAnotherStyleNoFunction()
    Dim parCountDown, i, sMyPar
    parCountDown = ActiveDocument.Paragraphs.Count
    For i = parCountDown To 1 Step -1
        If ActiveDocument.Paragraphs(i).Style = "myStyleOne" Then 'change the part for: "Normal"
            ActiveDocument.Paragraphs(i).Style = "myStyleTwo" 'change the part for: "Heading 1"
            'sMyPar = ActiveDocument.Paragraphs(i).Range.Text
            'MsgBox (sMyPar) 'message box with that paragraph
            Exit Sub
        End If
    Next
End Sub

So you see here three ways to do the same thing and easy path to copy all that. Stay tuned and Good luck!