使用Grep或AWK命令

Question

I have file with this text information:

http://=
en.domain.com/registration.html#/?doitoken=1D7f1ad404-f84b-4a3b-8931=
-4f40b619730e



http://=
en.domain.com/registration.html#/?doitoken=5D8172f6e6-240f-42e6-8512=
-6d7f6bd61c2d



http://=
en.domain.com/registration.html#/?doitoken=8D8172f6e6-240f-42e6-8512=
-6d7f6bd61c2d

How i can do this using grep or awk command in linux bash:

http://en.domain.com/registration.html#/?doitoken=1D7f1ad404-f84b-4a3b-8931-4f40b619730e
http://en.domain.com/registration.html#/?doitoken=5D8172f6e6-240f-42e6-8512-6d7f6bd61c2d
http://en.domain.com/registration.html#/?doitoken=8D8172f6e6-240f-42e6-8512-6d7f6bd61c2d

Thanks for your answers!

Answer 1

awk 'BEGIN{FS="=\n"; RS=""; OFS=""} {print $1, $2, $3}' input_file

您还可以摆脱OFS=""并删除print语句中的, s

Answer 2

Save the program as pr.awk , and run awk -f pr.awk input.dat

NF {
    n++
    sub(/=$/, "")
    ans = ans $0
}

n==3 { # flush
    print ans
    ans = ""; n = 0 
}

Answer 3

$ awk '/=$/{sub(/=$/,""); printf "%s",$0;next} /./{print}' file
http://en.domain.com/registration.html#/?doitoken=1D7f1ad404-f84b-4a3b-8931-4f40b619730e
http://en.domain.com/registration.html#/?doitoken=5D8172f6e6-240f-42e6-8512-6d7f6bd61c2d
http://en.domain.com/registration.html#/?doitoken=8D8172f6e6-240f-42e6-8512-6d7f6bd61c2d

How it works:

• /=$/{sub(/=$/,""); printf "%s",$0;next}

  If the line ends with = , then remove the trailing = , print the result (without a trailing newline) and jump to the next line.

• /./{print}

  If we get here, then this line does not end with = and we just print it normally (with the trailing newline).