Delphi - OSX - 从内存流中加载字体

Question

I am trying to load a font from a memory stream on OSX in a Firemonkey (FMX) application with Delphi.

Here is the code I tried:

procedure LoadFontFromStream(SourceStream:TStream);
var cfData:CFDataRef;
    fontBuffer:TBytes;
    fontRef: CGFontRef;
    provider: CGDataProviderRef;
    currentStrRef: CFStringRef;
    currentStr: string;
    streamSize: Int64;
    ctFontReference : CTFontRef;
    ctAscent, ctDescent, ctCapHeight: CGFloat;
begin
  streamSize := SourceStream.Size;
  SetLength(fontBuffer, streamSize);
  SourceStream.Read(fontBuffer[0], streamSize);

  cfData := CFDataCreateWithBytesNoCopy(kCFAllocatorDefault, @fontBuffer[0],
    streamSize, kCFAllocatorNull);
  provider := CGDataProviderCreateWithCFData(cfData);
  CFRelease(cfData);

  fontRef := CGFontCreateWithDataProvider(provider);
  CGDataProviderRelease(provider);

  if fontRef <> nil then
  begin
    ctFontReference := CTFontCreateWithGraphicsFont(fontRef,0.0, nil, nil);
    if ctFontReference <> nil then
    begin
      ctCapHeight := CTFontGetCapHeight(ctFontReference);
      ctAscent := CTFontGetAscent(ctFontReference);
      ctDescent := CTFontGetDescent(ctFontReference);
    end;
    currentStrRef := CTFontCopyFamilyName(ctFontReference);
    currentStr := CFToDelphiString(currentStrRef);
    Log.d('Family name: %s',[currentStr]);
    CFRelease(currentStrRef);
    currentStrRef := CTFontCopyPostscriptName(ctFontReference);
    currentStr := CFToDelphiString(currentStrRef);
    Log.d('Postscript name: %s',[currentStr]);
    CFRelease(currentStrRef);
    currentStrRef := CTFontCopyDisplayName(ctFontReference);
    currentStr := CFToDelphiString(currentStrRef);
    Log.d('Display name: %s',[currentStr]);
    CFRelease(currentStrRef);
  end;
end;

The familyname, postscript name and display name all display correct on the debugger. However, the font is not loaded/displayed on my form. I tried enumerating all font families after running the code and it seems my font (Open Sans) is not present. Here is how I enumerate the font families:

procedure ListFonts();
var fontFamilyArray: CFArrayRef;
    i : CFIndex;
    NumFamilies: CFIndex;
    family: CFStringRef;
    familyStr: string;
    foundOpenSans: Boolean;
begin
  foundOpenSans := False;
  fontFamilyArray := CTFontManagerCopyAvailableFontFamilyNames();
  NumFamilies  :=  CFArrayGetCount(fontFamilyArray);
  for i := 0 to NumFamilies-1 do
  begin
    family := CFArrayGetValueAtIndex(fontFamilyArray, i);
    familyStr := CFToDelphiString(family);
    if familyStr.StartsWith('Open') then
    begin
      foundOpenSans := true;
      Log.d('Found %s', [familyStr]);
    end;
  end;

  if not foundOpenSans then
    Log.d('Open Sans not found');

  CFRelease(fontFamilyArray);
end;

I know that loading custom fonts is possible by setting ATSApplicationFontsPath in the info.plist file and placing the files in a folder with my bundle. I tried that and that works. However, I need to load the font from a memory stream.

Any ideas why that code doesn't load the font? I am running the code to load the font before creating any forms in my app.

Answer 1

I don't see you registering that font with the font manager. Have a look at CTFontManagerRegisterGraphicsFont . The documentation explicitly mentions this function for registering fonts that were constructed from memory.

Answer 2

The problem was related to the buffer I used. Here is how I solved it.

procedure LoadFontFromStream(SourceStream:TStream);
var cfData:CFDataRef;
    fontBuffer:TBytes;
    fontRef: CGFontRef;
    provider: CGDataProviderRef;
    streamSize: Int64;
    theError: CFErrorRef;
    errorDescription : CFStringRef;
    errorDescriptionString : string;
    registerFontValue: Integer;
begin
  streamSize := SourceStream.Size;
  SetLength(fontBuffer, streamSize);
  SourceStream.Read(fontBuffer[0], streamSize);
  cfData := CFDataCreate(kCFAllocatorDefault, @fontBuffer[0],streamSize);
  provider := CGDataProviderCreateWithCFData(cfData);
  CFRelease(cfData);
  fontRef := CGFontCreateWithDataProvider(provider);
  CGDataProviderRelease(provider);
  if fontRef <> nil then
  begin
    theError := nil;
    registerFontValue :=CTFontManagerRegisterGraphicsFont(fontRef, @theError);
    if theError <> nil then
    begin
      errorDescription := CFErrorCopyDescription(theError);
      errorDescriptionString := CFToDelphiString(errorDescription);
      Log.d('Error loading font: %s', [errorDescriptionString]);
      CFRelease(errorDescription);
    end;
  end;
end;

However, this only works on OSX 10.8 and later as CTFontManagerRegisterGraphicsFont is not availabile on OSX 10.7. Any idea on what method is available on OSX 10.7?