尝试在计划/球拍中建立列表

Question

I'm very new to Scheme and can't grasp why this isn't working for me. I'm trying to return an ordered list from a BST structure, but can't seem to get it to cons or append the car to the list. I'm obviously doing something wrong. Any suggestions? Thanks.

(define (sortList lst)
  (printList '(16 (8 (2 () ()) (10 () ())) (20 (18 () ()) (30 () ()))) (list) )
)

(define (printList lst sorted)

  ; recur smaller
  (unless (null? (cadr lst))
    (cons (printList (cadr lst) sorted) sorted))

  ; debugging...
  (writeln (car lst))

  ; build sorted list
  (cons (car lst) sorted )

  ; recur larger
  (unless (null? (caddr lst))
    (cons (printList (caddr lst) sorted) sorted))

  ; return sorted lst
  sorted
)

Answer 1

I whipped up a quick solution:

(define (tree->list tree)
  (let recur ((x tree)
              (acc '()))
    (if (null? x)
        acc
        (recur (cadr x)
               (cons (car x)
                     (recur (caddr x) acc))))))

Example:

> (tree->list '(16 (8 (2 () ()) (10 () ())) (20 (18 () ()) (30 () ()))))
(2 8 10 16 18 20 30)

The way this works is that I have an accumulator ( acc ) which starts as an empty list. Then the recursive function ( recur ) checks if the current element is empty: if so, then don't change the accumulator; otherwise, recurse into the right-hand branch, then add the current element to the result, then recurse into the left-hand branch with that.

cons builds lists right-to-left, hence the recursion into the right-hand branch before the left-hand branch. (Otherwise, the list will come out reversed.)