有没有办法在Haskell中以编程方式生成一系列列表推导？

Question

In my ongoing attempt to get better at Haskell, I'm attempting to solve a problem where I'd like to create a series of list comprehensions of this form:

m2 = [[x1,x2] | x1 <- [2..110], x2 <- [x1..111]]
m3 = [[x1,x2,x3] | x1 <- [2..22], x2 <- [x1..22], x3 <- [x2..24]]
m4 = [[x1,x2,x3,x4] | x1 <- [2..10], x2 <- [x1..10], x3 <- [x2..10], x4 <- [x3..12]]
...

Where x1 <= x2 ... <= xn , the number following m is the length of the sublists, and the first n - 1 terms are bounded by the same upper bound, while the nth term is bounded by some larger number.

I could certainly write all of it out by hand, but that's not particularly good practice. I'm wondering if there's a way to generate these lists up to a particular maximum m value. My immediate thought was Template Haskell, but I don't know enough about it to determine whether it's usable. Is there some other solution that's escaping me?

In pseudo-Haskell, what I'm looking for is some method that does something like:

mOfN n bound term = [ [x1..xn] | x1 <- [2..bound], x2 <- [x1..bound], ..., xn <- [x(n-1)..term] ]

The main issue is that I can't figure out how I would dynamically create x1,x2, etc.

Answer 1

Is this what you are looking for?

import Data.List (tails)

mofn 0 xs = [ [] ]
mofn m xs = [ y:zs | (y:ys) <- tails xs, zs <- mofn (m-1) ys ]

ie mofn 3 [1..5] is:

[[1,2,3],[1,2,4],[1,2,5],[1,3,4],[1,3,5],[1,4,5],[2,3,4],[2,3,5],[2,4,5],[3,4,5]]

The key is the tails function which returns successive tails of a list.

Update

Is this what you are looking for?

mofn' 1 lo hi bnd = [ [x] | x <- [lo..bnd] ]
mofn' k lo hi bnd = [ x:ys | x <- [lo..hi], ys <- mofn' (k-1) x hi bnd ]

mofn' 3 1 3 5 is:

[[1,1,1], [1,1,2], [1,1,3], [1,1,4], [1,1,5],
 [1,2,2], [1,2,3], [1,2,4], [1,2,5],
 [1,3,3], [1,3,4], [1,3,5],
 [2,2,2], [2,2,3], [2,2,4], [2,2,5],
 [2,3,3], [2,3,4], [2,3,5],
 [3,3,3], [3,3,4], [3,3,5]
]