如何使用XSL从XML元素获取信息

Question

<start>
    <tag> dog=German shepherd|cat=has a lot of spots </tag>
</start>
<start>
    <tag> cat=black cat|dog=Clifford </tag>
</start>

Suppose I had an XML document like this and wanted to loop through it and select the value of cat and dog and print them separately using XSL how should I go about doing so?

Answer 1

Given a well-formed input XML, such as:

<root>
    <start>
        <tag> dog=German shepherd|cat=has a lot of spots </tag>
    </start>
    <start>
        <tag> cat=black cat|dog=Clifford </tag>
    </start>
</root>

and an XSLT 2.0 processor, you could apply the following stylesheet:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/root">
    <xsl:copy>
        <xsl:for-each select="start/tokenize(tag, '\|')">
            <entry>
                <key>
                    <xsl:value-of select="substring-before(., '=')" />
                </key>
                <value>
                    <xsl:value-of select="substring-after(., '=')" />
                </value>
            </entry>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

to receive:

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <entry>
      <key> dog</key>
      <value>German shepherd</value>
   </entry>
   <entry>
      <key>cat</key>
      <value>has a lot of spots </value>
   </entry>
   <entry>
      <key> cat</key>
      <value>black cat</value>
   </entry>
   <entry>
      <key>dog</key>
      <value>Clifford </value>
   </entry>
</root>