使用awk匹配每一列的行

Question

How can awk be used to find values that match in row 2 for each column?

I would like to take in a tab limited file and for each column if any row below row 2 matches what is in row 2, print field with "match".

transforming this tab delimited file:

header1 | header2 | header3
1       | 1       | B
--------+---------+----------
3       | 1       | A
2       | A       | B
1       | B       | 1

To this:

header1 | header2 | header3
1       | 1       | B
--------+---------+----------
3       | 1 match | A
2       | A       | B match
1 match | B       | 1

Answer 1

I would go for something like this:

$ cat file
header1 header2 header3
1       1       B
3       1       A
2       A       B
1       B       1
$ awk -v OFS='\t' 'NR == 2 { for (i=1; i<=NF; ++i) a[i] = $i }
    NR > 2 { for(i=1;i<=NF;++i) if ($i == a[i]) $i = $i " match" }1' file
header1 header2 header3
1       1       B
3       1 match A
2       A       B match
1 match B       1

On the second line, populate the array a with the contents of each field. On subsequent lines, add "match" when they match the corresponding value in the array. The 1 at the end is a common shorthand causing each line to be printed. Setting the output field separator OFS to a tab character preserves the format of the data.

Answer 2

Pedantically, with GNU Awk 4.1.1 :

awk -f so.awk so.txt
header1 header2 header3
1       1       B
3       1*      A
2       A       B*
1*      B       1

with so.awk :

{
    if(1 == NR) {
        print $0;
    } else if(2 == NR) {
        for(i = 1; i <= NF; i++) {
            answers[i]=$i;
        }
        print $0;
    } else {
        for(i = 1; i <= NF; i++) {
            field = $i;
            if(answers[i]==$i) {
                field = field "*" # a match
            }
            printf("%s\t",field);
        }
        printf("%s", RS);
    }
}

and so.txt as a tab delimited data file:

header1 header2 header3
1       1       B
3       1       A
2       A       B
1       B       1

This isn't homework, right...?