Spreadsheet :: ParseExcel建立数组或哈希

Question

I am new to Spreadsheet::ParseExcel . I have a space-delimited file which I opened in Microsoft Excel and saved it as a XLS file.

I installed Spreadsheet::ParseExcel and used the example code in documentation to print the contents of the file. My objective is to build an array of some of the data to write to a database. I just need a little help building the array -- writing to a database I'll figure out later.

I'm having a hard time understanding this module -- I did read the documentation, but because of my inexperience I'm unable to understand it.

Below is the code I'm using for the output.

#!/usr/bin/perl

use warnings;
use strict;

use Data::Dumper;
use Spreadsheet::ParseExcel;

my $parser   = Spreadsheet::ParseExcel->new();
my $workbook = $parser->parse( 'file.xls' );

if ( !defined $workbook ) {
    die $parser->error(), ".\n";
}

for my $worksheet ( $workbook->worksheets() ) {

    my ( $row_min, $row_max ) = $worksheet->row_range();
    my ( $col_min, $col_max ) = $worksheet->col_range();

    for my $row ( $row_min .. $row_max ) {

        for my $col ( $col_min .. $col_max ) {

            my $cell = $worksheet->get_cell( $row, $col );
            next unless $cell;

            print "Row, Col    = ($row, $col)\n";
            print "Value       = ", $cell->value(),       "\n";
            print "Unformatted = ", $cell->unformatted(), "\n";
            print "\n";
        }
    }
}

And here is some of the output

Row, Col    = (0, 0)
Value       = NewRecordFlag
Unformatted = NewRecordFlag

Row, Col    = (0, 1)
Value       = AgencyName
Unformatted = AgencyName

Row, Col    = (0, 2)
Value       = CredentialIdnt
Unformatted = CredentialIdnt

Row, Col    = (0, 3)
Value       = ContactIdnt
Unformatted = ContactIdnt

Row, Col    = (0, 4)
Value       = AgencyRegistryCardNumber
Unformatted = AgencyRegistryCardNumber

Row, Col    = (0, 5)
Value       = Description
Unformatted = Description

Row, Col    = (0, 6)
Value       = CredentialStatusDescription
Unformatted = CredentialStatusDescription

Row, Col    = (0, 7)
Value       = CredentialStatusDate
Unformatted = CredentialStatusDate

Row, Col    = (0, 8)
Value       = CredentialIssuedDate
Unformatted = CredentialIssuedDate

My objective is to build an array of CredentialIssuedDate , AgencyRegistryCardNumber , and AgencyName . Once I grasp the concept of doing that, I can go to town with this great module.

Answer 1

Here's a quick example of something that should work for you. It builds an array @rows of arrays of the three field values you want for each worksheet, and displays each result using Data::Dumper . I haven't been able to test it, but it looks right and does compile

It starts by building a hash %headers that relates the column header strings to the column number, based on the first row in each worksheet.

Then the second row onwards is processed, extracting the cells in the columns named in the @wanted array, and putting their values in the array @row , which is pushed onto @rows as each one is accumulated

#!/usr/bin/perl

use strict;
use warnings;

use Spreadsheet::ParseExcel;
use Data::Dumper;

my @wanted = qw/
    CredentialIssuedDate
    AgencyRegistryCardNumber
    AgencyName
/;

my $parser   = Spreadsheet::ParseExcel->new;
my $workbook = $parser->parse('file.xls');

if ( not defined $workbook ) {
    die $parser->error, ".\n";
}

for my $worksheet ( $workbook->worksheets ) {

    my ( $row_min, $row_max ) = $worksheet->row_range;
    my ( $col_min, $col_max ) = $worksheet->col_range;

    my %headers;

    for my $col ( $col_min, $col_max ) {
        my $header = $worksheet->get_cell($row_min, $col)->value;
        $headers{$header} = $col;
    }

    my @rows;

    for my $row ( $row_min + 1 .. $row_max ) {

        my @row;

        for my $name ( @wanted ) {
            my $col = $headers{$name};
            my $cell = $worksheet->get_cell($row, $col);
            push @row, $cell ? $cell->value : "";
        }

        push @rows, \@row;
    }

    print Dumper \@rows;
}

Answer 2

I was able to resolve this by using the Spreadsheet::BasicReadNamedCol module

#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
use Spreadsheet::BasicReadNamedCol;

my $xlsFileName = 'shit.xls';
my @columnHeadings = (
'AgencyName',
'eMail',
'PhysicalAddress1',
'PhysicalAddress2'
);

my $ss = new Spreadsheet::BasicReadNamedCol($xlsFileName) ||
die "Could not open '$xlsFileName': $!";
$ss->setColumns(@columnHeadings);

# Print each row of the spreadsheet in the order defined in
# the columnHeadings array
my $row = 0;
while (my $data = $ss->getNextRow())
{
   $row++;
   print join('|', $row, @$data), "\n";
}