从单元格中删除字符

Question

This formula removes everything except numbers:

Sub qwerty()
    For Each r In Selection
        vout = ""
        v = r.Text
        n = Len(v)
        For i = 1 To n
            ch = Mid(v, i, 1)
            If ch Like "[0-9]" Then
                vout = vout & ch
            End If
        Next i
        r.Value = vout
    Next r
End Sub  

How can I modify it so that it will keep numbers and decimal points?

Answer 1

To include . , include it in your Like expression

If ch Like "[0-9.]" Then

Answer 2

Better to use a Regexp than slowly loop character by character through an inital range loop:

Sub Quicker()
Dim X
Dim ObjRegex As Object
Dim lngRow As Long
Dim lngCOl As Long

Set ObjRegex = CreateObject("vbscript.regexp")
ObjRegex.Global = True
ObjRegex.Pattern = "[^0-9/.]"

X = Selection.Value2
For lngRow = 1 To UBound(X, 1)
   For lngCOl = 1 To UBound(X, 2)
        X(lngRow, lngCOl) = ObjRegex.Replace(X(lngRow, lngCOl), vbNullString)
   Next
Next

Selection.Value2 = X

End Sub