比较Excel Vba中的2个动态命名范围

Question

I want to compare 2 dynamic named ranges (OriData and Filterdata), and set Filterdata into ""(empty) if OriData and Filterdata are exactly identical (Filterdata is the results of twice advance filter of OriData, I want to zero it if both of them are identical). I barely manage to come out with this code but it always shows "Disimilar ranges". What's wrong with my code and I would appreciate deeply if you can come out with the edited code to suit my need (zero the Filterdata if identical)

Sub Santa()
    Dim Dn As Range

    For Each Dn In Range("OriData")

        If Not Dn = Range("Filterdata").Cells(Dn.Row, Dn.Column) Then MsgBox "Disimilar ranges": Exit Sub

    Next Dn

    MsgBox "Both Ranges have the same data"

End Sub

Im really new in vba so please bear with me... Thanks in advance!

Answer 1

The Dn.Row and Dn.Column are the row and column on the worksheet, not the relative row within Range("OriData"). When you try to reference the sister cell in Range("Filterdata"), you are not referencing the same cell position.

Sub Santa()
    Dim r As Long, c As Long

    If Range("OriData").Count <> Range("Filterdata").Count Then
        MsgBox "Dissimilar range sizes"
        Exit Sub
    End If

    For r = 1 To Range("OriData").Rows.Count
        For c = 1 To Range("OriData").Columns.Count
            If Not Range("OriData").Cells(r, c) = Range("Filterdata").Cells(r, c) Then
                MsgBox "Dissimilar range values"
                Exit Sub
            End If
        Next c
    Next r

    MsgBox "Both Ranges have the same data"

End Sub

Answer 2

This uses a diffent approach. When the ranges are huge, looping through the worksheet is inefficient. Here, the ranges are copied into variables first, then compared. If identical, the named range is either cleared (the values are deleted) or deleted (values and named range) - uncomment if needed.

Error checking is included.

The code uses meaningful variable names to help with understanding and maintaining it over time:

Sub DeleteIfIdentical()
    Dim r As Long, c As Long
    Dim ub1 As Long, ub2 As Long
    Dim original, filtered   ' arrays holding the named ranges' values

    On Error GoTo NoSuchRange
    original = Range("original")
    filtered = Range("filtered")
    On Error GoTo 0

    ub1 = UBound(original, 1)
    ub2 = UBound(original, 2)
    If Not (UBound(filtered, 1) = ub1) And _
           (UBound(filtered, 2) = ub2) Then
        MsgBox "Ranges are not identical!"
        Exit Sub
    End If

    For r = 1 To ub1
        For c = 1 To ub2
            If original(r, c) <> filtered(r, c) Then
                MsgBox "Ranges are not identical!"
                Exit Sub
            End If
        Next c
    Next r

    MsgBox "Both Ranges have the same data"
    Range("filtered").Clear   ' to clear all values
    '   Range("filtered").Delete  ' to clear all values and delete the named range
    Exit Sub

NoSuchRange:
    MsgBox "Error accessing named ranges 'orginal' and/or 'filtered'"
End Sub