VBA错误：类型不匹配

Question

I want to look from a column in excel for the names "JOHN", "PETER", "ALAN", "ALI" with only one if statements as you see below. I got an error message Type mismatch.

Can any please help me?

Option Explicit

Sub name()

    Dim i As Long, nam As String
    nam = Array("JOHN", "PETER", "ALAN", "ALI")
    For i = 1 To 3000
        If Worksheets("CONTACTS").Cells(i, 1).Value = nam Then
            Worksheets("CONTACTS").Cells(i, 5).Value = "good"
        End If
    Next i

End Sub

Answer 1

I've reworked your loop through the worksheet cells into a bulk memory operation.

Sub name_check()
    Dim i As Long, n As Long, a As Long
    Dim nam As Variant, colAs As Variant

    nam = Array("JOHN", "PETER", "ALAN", "ALI")
    i = 3000

    With Worksheets("CONTACTS")
        colAs = .Cells(1, 1).Resize(i, 2).Value2

        For a = LBound(colAs, 1) To UBound(colAs, 1)
            colAs(a, 2) = vbNullString
            For n = LBound(nam) To UBound(nam)
                If UCase(colAs(a, 1)) = nam(n) Then
                    colAs(a, 2) = "good"
                    Exit For
                End If
            Next n
        Next a

        .Cells(1, 5).Resize(i, 1) = Application.Index(colAs, 0, 2)
    End With

End Sub

All of the looping and individual variable assignment is done within two variant arrays. Only when those operations are complete are the results returned to the worksheet en masse .

Answer 2

There seem to be two issues: first, my excel complains with the array initialization, so i'm using variant instead of string; second, poolie is right - loop through the array. This should be what you want:

Sub Button1_Click()
 Dim i As Long, nam As Variant
    nam = Array("JOHN", "PETER", "ALAN", "ALI")
    For i = 1 To 30
        For j = 0 To UBound(nam)
            If Worksheets("CONTACTS").Cells(i, 1).Value = nam(j) Then
                Worksheets("CONTACTS").Cells(i, 5).Value = "good"
            End If
        Next j
    Next i
End Sub

Answer 3

You seem to be comparing the value to an array. You probably need to use a loop to check if the value in the cell is any of the names you're looking for.

(I'm not a VBA expert so I can't give you the code.)