将记录复制到动态分配的内存时，Delphi 7引用计数错误

Question

I faced a strange behavior in Delphi when assigning a record type variable with a managed string field to a dynamically allocated buffer. What's wrong with it and how could be corrected?

type
  PRec = ^TRec;
  TRec = packed record
    Foo: integer;
    Bar: string;
  end;

procedure Error;
var
  P, Q: PRec;
  R, T: TRec;
begin
  R.Foo := 1;
  R.Bar := 'Bar';
  T := R; // Ready
  Q := @T;
  Q^ := R; // Ready
  GetMem(P, SizeOf(TRec));
  P^ := R; // Access violation in _LStrAsg at 
           // "MOV     ECX,[EDX-skew].StrRec.refCnt"

  R := P^; // Just to keep reference while debugging
end;

Answer 1

Your record is a managed record. As such, it needs to be initialized. Your code uses GetMem which does not initialize the record. Instead you should use New . Replace

GetMem(P, SizeOf(TRec));

with

New(P);

Likewise when you need to deallocate, you must finalize the record. Use Dispose rather than FreeMem .

It is possible to initialize and finalize manually if, for some reason, you need to do that. That would look like this:

// allocate and initialize
GetMem(P, SizeOf(P^));
Initialize(P^);

// finalize and deallocate
Finalize(P^);
FreeMem(P);