更改/更改单元格值Excel VBA的第N个元素

Question

I was creating a macro to reverse the capitalization of cell values, to explain better.

Original values-

hh3crd220
xmi4Idc200
TEst02NoW

Output-

HH3CRD220
XMI4iDC200
teST02nOw

I think there must already be macros which would do the job, but i was coding one myself, everything works fine except changing the nth value, Mid is not working since it will only extract the value, i tried Character but that will only format the element, i wanted something like character.value or mid.value function to work.

Sub CapsChange()
Dim letr As String
Dim Val1 As String

Dim sr As Range
lastrow = ActiveSheet.Cells(ActiveSheet.Rows.Count, "A").End(xlUp).Row

Set sr = Range("A1:A" & lastrow)

For Each r In sr
Fval = r.Value
Val1 = Left(r.Value, 1)

If Val1 <> UCase(Val1) Then

For i = 1 To Len(Fval)
    letr = Mid(Fval, i, 1)
    If letr = UCase(letr) Then

**'First Code try**
    letr = LCase(letr)
**'Second Code try**
    r.Characters(i, 1).Value = LCase(letr)
    Else
    letr = UCase(letr)
    r.Characters(i, 1).Value = UCase(letr)
    End If
Next i

End If

Next

End Sub

Just Need Help changing/controlling the nth character of cell value, like we use cell(x,y).value = XXX.

Answer 1

try this:

variant 1 using SUB()

Sub Test()
    Dim rng As Range, cl As Range, i&
    Set rng = Range("A1:A" & Cells(ActiveSheet.Rows.Count, "A").End(xlUp).Row)
    For Each cl In rng.Cells
        For i = Len(cl.Value) To 1 Step -1
            With cl.Characters(i, 1)
                If .Text = UCase(.Text) Then
                    .Text = LCase(.Text)
                ElseIf .Text = LCase(.Text) Then
                    .Text = UCase(.Text)
                End If
            End With
    Next i, cl
End Sub

variant 2 using Function()

Public Function ReverseCase(cl As Range)
    Dim StringOutput$, i&
    For i = Len(cl.Value) To 1 Step -1
        With cl.Characters(i, 1)
            If .Text = UCase(.Text) Then
                StringOutput = LCase(.Text) & StringOutput
            ElseIf .Text = LCase(.Text) Then
                StringOutput = UCase(.Text) & StringOutput
            End If
        End With
    Next i
    ReverseCase = StringOutput
End Function

test for function()

both variants are tested, works fine

Answer 2

Something like the below function would be far easier to re-use!

Here is how to use it :

Option Explicit

Sub test_Angad_Arora()
Dim wS As Worksheet, _
    LastRow As Long, _
    i As Long

Set wS = ActiveSheet
With wS
    LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row

    For i = 1 To LastRow
        .Cells(i, 1) = InvertCaseCore(.Cells(i, 1))
    Next i
End With
End Sub

And the function that invert the capatilization of the inputed string:

Public Function InvertCaseCore(StringToReCapitalize As String)

Dim l As Integer, _
    c As String, _
    OutPut As String, _
    i As Integer

l = Len(StringToReCapitalize)
For i = 1 To l
     c = Mid(StringToReCapitalize, i, 1)
     If (c >= "A") And (c <= "Z") Then
         c = LCase(c)
     ElseIf (c >= "a") And (c <= "z") Then
         c = UCase(c)
     End If
     OutPut = OutPut & c
 Next i

    InvertCaseCore = OutPut
End Function

Answer 3

You can use the Mid statement , which allows in place modification of a string:

Sub CapsChange()
    Dim letr As String
    Dim Val1 As String

    Dim sr As Range
    lastrow = ActiveSheet.Cells(ActiveSheet.Rows.Count, "A").End(xlUp).Row

    Set sr = Range("A1:A" & lastrow)

    For Each r In sr
        Fval = r.Value
        Val1 = Left(r.Value, 1)

        If Val1 <> UCase(Val1) Then

            For i = 1 To Len(Fval)
                letr = Mid(Fval, i, 1)
                If letr = UCase(letr) Then
                    Mid(Fval,i,1) = LCase(letr)
                else
                    Mid(Fval,i,1) = UCase(letr)
                End If
            Next i

        End If

    Next

End Sub

Answer 4

You're looking for the replace -Function ( See this link ). An example:

Replace("abCabCde", "C", "c", , 1)

This will find the first (and only the first) occurrence of "C" in "abCabCde" and replaces it with "c" to get "abcabCde".