数组中元素的限制值 (VBA)

Question

I have an array of numbers, say [1 2 3 4 5 6 7 8 9 10] and I want to set a limiting value that all numbers over this value are set to - eg. a limiting value of 5 would produce [1 2 3 4 5 5 5 5 5 5] .

I'm looking to do this on a much larger scale and I need to loop through a large number of times; what's the most efficient a least resource-hungry method of doing this? I could loop over it but is there an in-built/more efficient way?

Thanks in advance!

Answer 1

Add a class to your project that only allows values to a preset maximum.

Right click ThisWorkbook in the VBE's Project Explorer and choose Insert ► Class module. Paste the following into the new code sheet titled something like Book1 - Class1 (Code) .

Option Explicit

Private pVAL As Long
Private Const maxVAL As Long = 5  'set the maximum value here

Public Property Get val() As Long
    val = pVAL
End Property

Public Property Let val(Value As Long)
    If Value > maxVAL Then
        pVAL = maxVAL
    Else
        pVAL = Value
    End If
End Property

The maximum allowed value is set by a const at the top of the page. This allows you to change it in one place rather than searching for a hard-coded value in several places. With an eye to your sample data, I've used a long type. You may wish to switch to another numerical variable type declaration. When that has been pasted in, open the VBE's Properties window ( F4 ) and rename the class. My example uses maxVAL .

In a module sheet, paste the following test code.

Sub classTest()
    Dim a As Long, mVals() As New maxVAL, sVal As New maxVAL

    sVal.val = 3
    Debug.Print sVal.val
    sVal.val = 11
    Debug.Print sVal.val

    ReDim mVals(1 To 10)
    For a = LBound(mVals) To UBound(mVals)
        mVals(a).val = a
    Next a

    For a = LBound(mVals) To UBound(mVals)
        Debug.Print mVals(a).val
    Next a

End Sub

Run the sub and check the VBE's Immediate window for the results. They should be similar to the following.

classTest
 3 
 5 
 1 
 2 
 3 
 4 
 5 
 5 
 5 
 5 
 5 
 5