下一页续表

Question

I ran into this problem using proc report and ods rtf. I want to create a listing with a lot of columns which don't fit on one page. The problem is that the second part of columns don't print immediately on the following page but it prints after the whole first part of listing is printed. So I don't have it on a second page as I would like to but for example on page 15 which makes it look very chaotic.

Is there some way how to change it? I don't know if it is a proc report problem or ods rtf problem.

Thank you in advance for your help.

Answer 1

Try inserting a page break:

data test0;
  array vars{20} $;
  do i = 1 to 100;
    do j = 1 to 20;
      vars{j} = put(rand('Normal'),8.4);
    end;
    output;
  end;
run;

data test;
  set test0;
  pageno = ceil(_n_/37);
run;

ods rtf file='test.rtf';

proc report data=test headline nowd;
  column pageno vars1 - vars20;
  define pageno / order noprint;
  break after pageno / page;
run;

ods rtf close;

In this example, I have determined that exactly 37 lines of the table fit on a page, so I created pageno which allows me to break the table after 37 lines. When I use proc report , remember to include pageno in your column statement and define it as an order or group variable. Using the break statement actually causes the breaks to appear.