如何将几个指定的文件从源文件夹及其子文件夹复制到目标文件夹？

Question

I have source folder: c:\\prefix\\bin

I want to copy a set of specified files from source folder and its subfolders.

Lets say I want to copy:

bin
... gtsam.dll
... msvcr120.dll
... intel64\
    ... vc12\
        ... tbb.dll

To be more clearly for what I want to copy:

.\gtsam.dll .\msvcr120.dll .\intel64\vc12\tbb.dll

There are many files in the source directory and many subdirectories that I don't want to copy. And all the specified files I have to copy do not share a wild card. They are not all *.dll to copy to c:\\dst

How I can do it with the most elegant way?

Using copy , or xcopy , or robocopy ?

Answer 1

I suggest to create first a simple text file containing line by line the files to copy with relative path.

Example for FilesList.txt :

gtsam.dll
msvcr120.dll
intel64\vc12\tbb.dll

It is up to you in which directory to store this list file with the names of the files to copy.
The code below expects this file in directory C:\\prefix\\bin .

Then create a batch file with following code:

@echo off
pushd "C:\prefix\bin"
for /F "usebackq delims=" %%F in ("FilesList.txt") do (
    %SystemRoot%\System32\xcopy.exe "%%~F" C:\dst\ /C /H /I /K /Q /R /Y >nul
)
popd

If target is specified with a backslash at end as done here and option /I is used, console application xcopy expects that C:\\dst is a directory and even creates the entire directory structure to this directory automatically if not already existing.

Or you use this script with command copy and making sure the destination directory exists before copying the files.

@echo off
if not exist "C:\dst" (
    md "C:\dst"
    if errorlevel 1 (
        echo.
        echo Failed to create directory C:\dst
        echo.
        pause
        goto :EOF
    )
)
pushd "C:\prefix\bin"
for /F "usebackq delims=" %%F in ("FilesList.txt") do (
    copy /B /Y "%%~F" C:\dst\ >nul
)
popd

Command md creates also entire directory tree on creating a directory with command extensions enabled as by default.

In both cases the directory C:\\dst contains after batch file execution:

• gtsam.dll
• msvcr120.dll
• tbb.dll

The main advantage of using a list file containing the names of the files to copy with relative path is easy updating in future without the need to change the batch code.

But let's say the files should be copied with duplicating the directory structure from source to destination directory resulting in directory C:\\dst containing after batch file execution:

• gtsam.dll
• msvcr120.dll
• intel64
  • vc12
    • tbb.dll

In this case the batch code with xcopy could be:

@echo off
setlocal EnableExtensions EnableDelayedExpansion
pushd "C:\prefix\bin"
if "%CD:~-1%" == "\" ( set "BasePath=%CD%" ) else ( set "BasePath=%CD%\" )

for /F "usebackq delims=" %%F in ("FilesList.txt") do (
    set "SourcePath=%%~dpF"
    set "RelativePath=!SourcePath:%BasePath%=!"
    %SystemRoot%\System32\xcopy.exe "%%~F" "C:\dst\!RelativePath!" /C /H /I /K /Q /R /Y >nul
)

popd
endlocal

And the batch code using copy could be:

@echo off
if not exist "C:\dst" (
    md "C:\dst"
    if errorlevel 1 (
        echo.
        echo Failed to create directory C:\dst
        echo.
        pause
        goto :EOF
    )
)

setlocal EnableDelayedExpansion
pushd "C:\prefix\bin"
if "%CD:~-1%" == "\" ( set "BasePath=%CD%" ) else ( set "BasePath=%CD%\" )

for /F "usebackq delims=" %%F in ("FilesList.txt") do (
    set "SourcePath=%%~dpF"
    set "RelativePath=!SourcePath:%BasePath%=!"
    md "C:\dst\!RelativePath!" 2>nul
    copy /B /Y "%%~F" "C:\dst\!RelativePath!" >nul
)

popd
endlocal

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• copy /?
• echo /?
• endlocal /?
• if /?
• for /?
• goto /?
• md /?
• pause /?
• popd /?
• pushd /?
• set /?
• setlocal /?
• xcopy /?

Answer 2

Not tested:

@echo off

set "basedir=c:\prefix\bin"
set "destination=c:\destination"

for /r "%basedir%" %%# in (*gtsam.dll *msvcr120.dll *tbb.dll) do (
  copy "%%~f#" "%destination%"
)