通过在Erlang列表中找到键来查找特定的元组（eJabberd HTTP标头）

Question

I am just getting started with eJabberd and am writing a custom module with HTTP access.

I have the request going through, but am now trying to retrieve a custom header and that's where I'm having problems.

I've used the Request record to get the request_headers list and can see that it contains all of the headers I need (although the one I'm after is a binary string on both the key and value for some reason...) as follows:

[
    { 'Content-Length', <<"100">> },
    { <<"X-Custom-Header">>, <<"CustomValue">> },
    { 'Host', <<"127.0.0.1:5280">> },
    { 'Content-Type', <<"application/json">> },
    { 'User-Agent', <<"Fiddler">> }
]

This is also my first foray into functional programming, so from procedural perspective, I would loop through the list and check if the key is the one that I'm looking for and return the value.

To this end, I've created a function as:

find_header(HeaderKey, Headers) ->
    lists:foreach(
        fun(H) ->
            if
                H = {HeaderKey, Value} -> H;
                true -> false
            end
        end,
        Headers).

With this I get the error:

illegal guard expression

I'm not even sure I'm going about this the right way so am looking for some advice as to how to handle this sort of scenario in Erlang (and possibly in functional languages in general).

Thanks in advance for any help and advice!

PhilHalf

Answer 1

The List that you have mentioned is called a "Property list", which is an ordinary list containing entries in the form of either tuples, whose first elements are keys used for lookup and insertion or atoms, which work as shorthand for tuples {Atom, true}.

To get a value of key, you may do the following:

proplists:get_value(Key,List).

for Example to get the Content Length:

7> List=[{'Content-Length',<<"100">>},
      {<<"X-Custom-Header">>,<<"CustomValue">>},
      {'Host',<<"127.0.0.1:5280">>},
      {'Content-Type',<<"application/json">>},
      {'User-Agent',<<"Fiddler">>}].

7> proplists:get_value('Content-Type',List).
<<"application/json">>

Answer 2

You can use the function lists:keyfind/3 :

> {_, Value} = lists:keyfind('Content-Length', 1, Headers).
{'Content-Length',<<"100">>}
> Value.
<<"100">>

The 1 in the second argument tells the function what tuple element to compare. If, for example, you wanted to know what key corresponds to a value you already know, you'd use 2 instead:

> {Key, _} = lists:keyfind(<<"100">>, 2, Headers).
{'Content-Length',<<"100">>}
> Key.
'Content-Length'

---

As for how to implement this in Erlang, you'd write a recursive function.

Imagine that you're looking at the first element of the list, trying to figure out if this is the entry you're looking for. There are three possibilities:

1. The list is empty, so there is nothing to compare.
2. The first entry matches. Return it and ignore the rest of the list.
3. The first entry doesn't match. Therefore, the result of looking for this key in this list is the same as the result of looking for it in the remaining elements: we recurse.

find_header(_HeaderKey, []) ->
    not_found;
find_header(HeaderKey, [{HeaderKey, Value} | _Rest]) ->
    {ok, Value};
find_header(HeaderKey, [{_Key, _Value} | Rest]) ->
    find_header(HeaderKey, Rest).

Hope this helps.